provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/documents/payoneer-program-move/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_vpc" "main" {
  tags = {
    Name = "prod"
  }
}

data "aws_subnets" "private" {
  filter {
    name   = "vpc-id"
    values = [data.aws_vpc.main.id]
  }

  tags = {
    Name = "private0*"
  }
}


#################################
#
# lambda configuration
#
##################################
module "lambda_documents_payoneer_program_move" {
  source                   = "git@github.com:theorchard/terraform-lambda.git?ref=3.1.5"
  environment              = var.environment
  lambda_name              = var.service_name
  lambda_description       = "Change the payoneer program for specific account"
  datadog_enabled          = var.datadog_enabled
  datadog_advanced_enabled = var.datadog_advanced_enabled

  application_family       = var.application_family

  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  lambda_function_timeout                           = "300"
  use_container_image                               = true

  vpc_enabled             = true
  vpc_id                  = data.aws_vpc.main.id
  vpc_subnet_ids          = data.aws_subnets.private.ids
  zappa_s3_policy_enabled = false


  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    KAFKA_BROKERS = var.kafka_brokers
  }

  msk_event_enabled                      = true
  event_source_mapping_batch_size        = 1
  event_source_mapping_msk_cluster_name  = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid  = var.trigger_msk_cluster_uuid
  event_source_mapping_starting_position = "LATEST"
  msk_topics = [
    "event.payee.programMove"
  ]

  iam_managed_policy_attachments = [
    module.lambda_documents_payoneer_program_move_owsrequest.policy_arn_output
  ]

}

module "lambda_documents_payoneer_program_move_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.service_name
}

module "datadog_lambda_documents_payoneer_program_move" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.10.0"

  environment                       = var.environment
  service_name                      = var.service_name
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-The_Orchard-documents-public"
  escalation_notification_endpoints = "@slack-The_Orchard-documents-public"
}

module "lambda_documents_payoneer_program_move_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.0.1"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  teams              = [var.environment]
  application_family = var.application_family
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.3.1"

  environment                         = var.environment
  service_name                        = var.service_name
  application_family                  = var.application_family
}