terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/fivetran/ows-coda/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "fivetran_group" "ows_coda" {
  id = "gentry_invitro"
}

data "aws_rds_cluster" "prod_ows_coda" {
  cluster_identifier = "${var.environment}-${var.service_name}"
}

resource "fivetran_connector" "prod_ows_coda_connector" {
  group_id = data.fivetran_group.ows_coda.id
  service  = "aurora"

  destination_schema {
    prefix = "prod_ows_coda"
  }

  config {
    host            = data.aws_rds_cluster.prod_ows_coda.endpoint
    port            = data.aws_rds_cluster.prod_ows_coda.port
    connection_type = "SshTunnel"
    user            = "fivetran"
    database        = "coda"
    tunnel_host     = "fivetran.theorchard.io"
    tunnel_port     = "2222"
    tunnel_user     = "fivetran"
    update_method   = "BINLOG"
  }
}

resource "fivetran_connector_schedule" "prod_ows_coda_connector_schedule" {
  connector_id   = fivetran_connector.prod_ows_coda_connector.id
  sync_frequency = 360
}

resource "fivetran_connector_schema_config" "main" {
  connector_id           = fivetran_connector.prod_ows_coda_connector.id
  schema_change_handling = "ALLOW_COLUMNS"
  schemas = {
    coda = {
      enabled = true
      tables = { for table in var.ows_coda_tables_to_sync_to_snowflake : table => {
        enabled   = true
        sync_mode = "SOFT_DELETE"
      } }
    }
  }
}