provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/frontend-collaborator-suite/awal/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.service_name}-waf-block"
  scope = "CLOUDFRONT"
}

resource "aws_route53_record" "route53_record" {
  name    = var.service_name_subdomain
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.3.0"
  providers = {
    aws.primary  = aws
    aws.failover = aws.aws_us_west_2
  }
  environment         = var.environment
  service_name        = var.service_name_suffix
  application_family  = var.application_family
  brand               = var.service_name
  domain_name         = var.real_domain_name
  default_root_object = "index-awal.html"
  additional_aliases = [
    "collaborators.${var.domain_name}",
    "collaborators.${var.real_domain_name}"
  ]
  custom_logging_bucket               = "prod-orcd-cloudfront-logs"
  custom_waf_name                     = data.aws_wafv2_web_acl.waf.name
  custom_response_headers_policy_name = "${var.environment}-${var.service_name}-${var.service_name_suffix}"
}

resource "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name    = "${var.environment}-${var.service_name}-${var.service_name_suffix}"
  comment = "${var.service_name_suffix}.${var.domain_name}"

  security_headers_config {
    content_type_options {
      override = true
    }

    frame_options {
      frame_option = "DENY"
      override     = true
    }

    referrer_policy {
      referrer_policy = "strict-origin-when-cross-origin"
      override        = true
    }

    strict_transport_security {
      access_control_max_age_sec = 365 * 24 * 60 * 60
      override                   = true
    }

    xss_protection {
      protection = true
      mode_block = true
      override   = true
    }
  }
}