provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/frontend-collaborator-suite/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "frontend_collaborator_suite_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.0.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = "frontend-${var.service_name_suffix}"
  teams              = [var.environment]
  application_family = var.application_family
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.service_name}-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.3.0"
  providers = {
    aws.primary  = aws
    aws.failover = aws.aws_us_west_2
  }
  environment         = var.environment
  service_name        = var.service_name_suffix
  application_family  = var.application_family
  brand               = var.service_name
  domain_name         = var.domain_name
  default_root_object = "index.html"
  additional_aliases = [
    "collaborators.${var.domain_name}",
  ]
  custom_logging_bucket               = "prod-orcd-cloudfront-logs"
  custom_waf_name                     = data.aws_wafv2_web_acl.waf.name
  custom_response_headers_policy_name = "${var.environment}-${var.service_name}-${var.service_name_suffix}"
}

resource "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name    = "${var.environment}-${var.service_name}-${var.service_name_suffix}"
  comment = "${var.service_name_suffix}.${var.domain_name}"

  security_headers_config {
    content_type_options {
      override = true
    }

    frame_options {
      frame_option = "DENY"
      override     = true
    }

    referrer_policy {
      referrer_policy = "strict-origin-when-cross-origin"
      override        = true
    }

    strict_transport_security {
      access_control_max_age_sec = 365 * 24 * 60 * 60
      override                   = true
    }

    xss_protection {
      protection = true
      mode_block = true
      override   = true
    }
  }
}

# Datadog API key secret and related IAM resources for Jenkins to upload sourcemaps

module "datadog_sourcemaps_api_key" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.1.0"

  environment                    = var.environment
  service_name                   = "frontend-collaborator-suite"
  secret_name                    = var.datadog_sourcemaps_api_key_secret_name
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      module.datadog_sourcemaps_api_key.secret_arn,
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretManager Access Policy
resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-frontend-collaborator-suite-datadog-api-key-access-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Jenkins agents will assume this role in order to access SecretManager
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "frontend-collaborator-suite-pipeline-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SecretManager access policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "frontend_collaborator_suite_pipeline_secret_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}