provider "aws" {
  region = var.region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}


terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/frontend-content/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "frontend_content_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=2.0.0"

  environment  = var.environment
  platform     = "javascript"
  service_name = "frontend-${var.service_name}"
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${var.domain_name}"
  statuses = ["ISSUED"]
}

data "aws_s3_bucket" "bucket_primary" {
  bucket = "${var.environment}-orcd-cdn"
}

data "aws_s3_bucket" "bucket_failover" {
  bucket   = "${var.environment}-orcd-cdn-us-west01"
  provider = aws.aws_us_west_2
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.brand}-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}


module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.3.0"
  providers = {
    aws.primary  = aws
    aws.failover = aws.aws_us_west_2
  }

  environment                              = var.environment
  brand                                    = var.brand
  service_name                             = var.service_name
  application_family                       = var.application_family
  domain_name                              = var.domain_name
  default_root_object                      = "index.html"
  custom_logging_bucket                    = var.cloudfront_logging_bucket
  custom_waf_name                          = data.aws_wafv2_web_acl.waf.name
  custom_origin_primary_s3_bucket_name     = data.aws_s3_bucket.bucket_primary.id
  custom_origin_failover_s3_bucket_name    = data.aws_s3_bucket.bucket_failover.id
  cloudfront_function_publish_changes_live = false
}