provider "aws" {
  region = var.region
}

provider "aws" {
  alias  = "failover"
  region = "us-west-2"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/frontend-royalties/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "cloudflare_zone" "cloudflare_zone" {
  name = var.domain_name
}

module "frontend_royalties_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.0.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = "frontend-royalties"
  application_family = var.application_family
}

data "aws_s3_bucket" "bucket_primary" {
  bucket = "${var.environment}-orcd-cdn"
}

data "aws_s3_bucket" "bucket_failover" {
  bucket   = "${var.environment}-orcd-cdn-us-west01"
  provider = aws.failover
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.3.0"
  providers = {
    aws.primary = aws
    aws.failover = aws.failover
  }

  environment                           = var.environment
  service_name                          = var.service_name
  application_family                    = var.application_family
  brand                                 = var.brand
  domain_name                           = var.domain_name
  default_root_object                   = "index.html"
  additional_aliases                    = ["abacus.${var.domain_name}"]
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = data.aws_s3_bucket.bucket_primary.id
  custom_origin_failover_s3_bucket_name = data.aws_s3_bucket.bucket_failover.id
}

resource "cloudflare_record" "public_dns_record" {
  name    = "abacus"
  proxied = true
  ttl     = 1
  type    = "CNAME"
  value   = module.spa_environment.cloudfront_distribution_domain_name
  zone_id = data.cloudflare_zone.cloudflare_zone.id
}