module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  alias  = "failover"
  region = "us-west-2"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/frontend-settings/sme/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

resource "aws_acm_certificate" "tls_cert" {
  domain_name               = "settings.${var.domain_name}"
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn         = aws_acm_certificate.tls_cert.arn
  validation_record_fqdns = aws_acm_certificate.tls_cert.domain_validation_options[*].resource_record_name
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374: Ensure AWS CloudFront web distribution has geo restriction enabled
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.0"
  providers = {
    aws.primary = aws
    aws.failover = aws.failover
  }

  environment                           = var.environment
  service_name                          = var.service_name
  application_family                    = var.application_family
  acm_certificate_cn                    = var.service_name
  brand                                 = var.brand
  domain_name                           = var.domain_name
  custom_logging_bucket                 = "prod-orcd-cloudfront-logs"
  default_root_object                   = "index-sme.html"
  additional_aliases                    = ["${var.service_name}.${var.domain_name}"]
  custom_waf_name                       = data.aws_wafv2_web_acl.waf.name
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = "${var.environment}-orcd-cdn"
  custom_origin_failover_s3_bucket_name = "${var.environment}-orcd-cdn-us-west01"
}