provider "aws" {
  region = var.aws_region
}

# This is the region of the failover bucket
provider "aws" {
  region = "us-west-2"
  alias  = "failover"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/frontend-solfege/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "cloudflare_zone" "cloudflare_zone" {
  name = var.domain_name
}

data "aws_s3_bucket" "bucket_primary" {
  bucket = "${var.environment}-orcd-cdn"
}

data "aws_s3_bucket" "bucket_failover" {
  bucket   = "${var.environment}-orcd-cdn-us-west01"
  provider = aws.failover
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary = aws
    aws.failover = aws.failover
  }

  environment                           = var.environment
  service_name                          = var.service_name
  application_family                    = var.application_family
  brand                                 = var.brand
  domain_name                           = var.domain_name
  default_root_object                   = "index.html"
  cloudfront_function_file_path         = "${path.module}/functions/viewer-request.js"
}

module "frontend_solfege_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=5.0.0"

  environment        = var.environment
  platform           = "javascript"
  service_name       = local.frontend_service_name
  application_family = var.application_family
}

resource "cloudflare_record" "public_dns_record" {
  name    = var.service_name
  proxied = true
  ttl     = 1
  type    = "CNAME"
  value   = module.spa_environment.cloudfront_distribution_domain_name
  zone_id = data.cloudflare_zone.cloudflare_zone.id
}