# Lambda defintion for create_vendor step (temporary it will be a healthcheck endpoint)

# allow making owsrequests from lambda
module "lambda_create_vendor_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = "lambda-create-vendor"
}

module "create_vendor_dynammodb_table" {
  source                         = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"
  env                            = var.environment
  table_name                     = "${var.service_name}-create-vendor"
  hash_key                       = var.hash_key
  server_side_encryption_enabled = true
  application_family             = var.application_family

  attribute = [
    {
      name = var.hash_key
      type = "S"
    }
  ]
}

# lambda defination
module "lambda_create_vendor" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment         = var.environment
  use_container_image = true
  lambda_name         = "lambda-create-vendor"
  lambda_description  = "For create_vendor step in step function."
  application_family  = var.application_family

  lambda_function_environment_variables = {
    Environment = var.environment
    LOGGER_DSN  = var.logger_dsn
    SENTRY_DSN  = module.sentry_gda_account_creation.sentry_key_dsn_public_output
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  datadog_advanced_enabled                       = false

  iam_managed_policy_attachments = [
    module.lambda_create_vendor_owsrequest.policy_arn_output,
    aws_iam_policy.dynamodb_vendor_policy.arn
  ]
}

data "aws_iam_policy_document" "dynamodb_vendor_crud_policy_document" {
  statement {
    sid    = "DynamoDBIndexAndStreamAccess"
    effect = "Allow"
    actions = [
      "dynamodb:GetShardIterator",
      "dynamodb:Scan",
      "dynamodb:Query",
      "dynamodb:DescribeStream",
      "dynamodb:GetRecords",
      "dynamodb:ListStreams",
    ]
    resources = [
      "${module.create_vendor_dynammodb_table.aws_dynamodb_table_arn}/index/*",
      "${module.create_vendor_dynammodb_table.aws_dynamodb_table_arn}/stream/*",
    ]
  }

  statement {
    sid    = "DynamoDBTableAccess"
    effect = "Allow"
    actions = [
      "dynamodb:BatchGetItem",
      "dynamodb:BatchWriteItem",
      "dynamodb:ConditionCheckItem",
      "dynamodb:PutItem",
      "dynamodb:DescribeTable",
      "dynamodb:DeleteItem",
      "dynamodb:GetItem",
      "dynamodb:Scan",
      "dynamodb:Query",
      "dynamodb:UpdateItem",
    ]
    resources = [
      module.create_vendor_dynammodb_table.aws_dynamodb_table_arn,
    ]
  }

  statement {
    sid    = "DynamoDBDescribeLimitsAccess"
    effect = "Allow"
    actions = [
      "dynamodb:DescribeLimits",
    ]
    resources = [
      module.create_vendor_dynammodb_table.aws_dynamodb_table_arn,
      "${module.create_vendor_dynammodb_table.aws_dynamodb_table_arn}/index/*",
    ]
  }
}

resource "aws_iam_policy" "dynamodb_vendor_policy" {
  name   = "Dynamo-${var.environment}-${var.service_name}-create-vendor-RW"
  policy = data.aws_iam_policy_document.dynamodb_vendor_crud_policy_document.json
}

# stage datadog creds and create dashboards.
module "datadog_lambda_create_vendor_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.15.3"

  environment                       = var.environment
  service_name                      = "lambda-create-vendor"
  lambda_invocation_monitor_enabled = false
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = "lambda-create-vendor"
  application_family = var.application_family
}