# Lambda defintion for send_success step (temporary it will be a healthcheck endpoint)

# allow making owsrequests from lambda
module "lambda_send_success_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = "lambda-send-success"
}

module "gda_account_creation_success_dynammodb_table" {
  source                         = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"
  env                            = var.environment
  table_name                     = "${var.service_name}-success"
  hash_key                       = var.hash_key
  server_side_encryption_enabled = true
  application_family             = var.application_family
  use_on_demand                  = true

  attribute = [
    {
      name = var.hash_key
      type = "S"
    }
  ]
}

# lambda defination
module "lambda_send_success" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  use_container_image      = true
  lambda_name              = "lambda-send-success"
  lambda_description       = "For send_success step in step function."
  application_family       = var.application_family
  datadog_advanced_enabled = var.datadog_advanced_enabled
  lambda_function_handler  = "src.app.handler"

  lambda_function_environment_variables = {
    Environment   = var.environment
    LOGGER_DSN    = var.logger_dsn
    SENTRY_DSN    = module.sentry_gda_account_creation.sentry_key_dsn_public_output
    KAFKA_BROKERS = var.kafka_brokers
    KAFKA_TOPIC   = var.success_kafka_topic
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled

  iam_managed_policy_attachments = [
    module.lambda_send_success_owsrequest.policy_arn_output,
    aws_iam_policy.dynamodb_policy.arn
  ]
}

data "aws_iam_policy_document" "dynamodb_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:GetItem",
      "dynamodb:PutItem"
    ]
    resources = [
      module.gda_account_creation_success_dynammodb_table.aws_dynamodb_table_arn
    ]
  }
}

resource "aws_iam_policy" "dynamodb_policy" {
  name   = "Dynamo-${var.environment}-${var.service_name}-send-success-RW"
  policy = data.aws_iam_policy_document.dynamodb_policy_document.json
}

# stage datadog creds and create dashboards.
module "datadog_lambda_send_success_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.15.3"

  environment                       = var.environment
  service_name                      = "lambda-send-success"
  lambda_invocation_monitor_enabled = false
}