# State Function defintion for GDA Account Creation flow.


# Step Function (SFN) root role policy document.
data "aws_iam_policy_document" "sfn_gda_account_creation_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
        "events.amazonaws.com",
      ]
    }
  }
}
# create iam role
resource "aws_iam_role" "sfn_gda_account_creation_assume_role" {
  name               = "${var.environment}-workflow-${var.service_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_gda_account_creation_assume_role.json
}


# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_gda_account_creation_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${var.service_name}",
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${var.service_name}:log-stream:*"
    ]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }
}
resource "aws_iam_role_policy" "sfn_gda_account_creation_log_event_policy_attachment" {
  name   = "${var.environment}-${var.service_name}-log-event-policy"
  role   = aws_iam_role.sfn_gda_account_creation_assume_role.id
  policy = data.aws_iam_policy_document.sfn_gda_account_creation_log_event_policy_document.json
}


# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "sfn_gda_account_creation_invoke_lambda_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_create_artist.lambda_arn,
      module.lambda_create_vendor.lambda_arn,
      module.lambda_send_failure.lambda_arn,
      module.lambda_send_success.lambda_arn,
      module.lambda_create_master_contact.lambda_arn,
      module.lambda_create_contract.lambda_arn,
      module.lambda_send_org_invite_email.lambda_arn,
      module.lambda_create_subscription.lambda_arn,
      module.lambda_redeem_voucher.lambda_arn,
      # todo: more to come
    ]

  }
}

# attach invoke lambda policy.
resource "aws_iam_role_policy" "sfn_gda_account_creation_invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.service_name}-lambda-role-policy"
  role   = aws_iam_role.sfn_gda_account_creation_assume_role.id
  policy = data.aws_iam_policy_document.sfn_gda_account_creation_invoke_lambda_policy_document.json
}


# Template for state machine.
data "template_file" "gda_account_creation_definition" {
  template = file("${path.module}/gda_account_creation.json")
  # all vars that are used in the json file.
  vars = {
    environment                                  = var.environment
    lambda_create_artist                         = module.lambda_create_artist.lambda_arn
    lambda_create_vendor                         = module.lambda_create_vendor.lambda_arn
    lambda_create_contract                       = module.lambda_create_contract.lambda_arn
    lambda_send_failure                          = module.lambda_send_failure.lambda_arn
    lambda_send_success                          = module.lambda_send_success.lambda_arn
    lambda_create_master_contact                 = module.lambda_create_master_contact.lambda_arn
    lambda_send_org_invite_email                 = module.lambda_send_org_invite_email.lambda_arn
    lambda_create_subscription                   = module.lambda_create_subscription.lambda_arn
    lambda_redeem_voucher                        = module.lambda_redeem_voucher.lambda_arn
    lambda_gda_account_creation_interval_seconds = var.lambda_gda_account_creation_interval_seconds
    lambda_gda_account_creation_retry_attempts   = var.lambda_gda_account_creation_retry_attempts
  }
}


resource "aws_sfn_state_machine" "gda_account_creation" {
  name       = "${var.environment}-workflow-${var.service_name}"
  role_arn   = aws_iam_role.sfn_gda_account_creation_assume_role.arn
  definition = data.template_file.gda_account_creation_definition.rendered
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = true
  }
  tracing_configuration {
    enabled = true
  }
}


data "aws_sfn_state_machine" "sfn_gda_account_creation_arn" {
  name = "${var.environment}-workflow-${var.service_name}"
}