module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/graphql-analytics/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

module "graphql_analytics_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.environment]
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.environment
  service_name                     = var.service_name
  application_family               = var.application_family
  redis_engine_version             = "5.0.6"
  cache_engine                     = "redis"
  cache_subnet_group_name          = "prod-vpc-orchard-subnet"
  cache_node_type                  = "cache.t4g.medium"
  cache_parameter_group_name       = "default.redis5.0"
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                           = module.vpc_info.vpc_id
  cache_transit_encryption_enabled = true
  additional_cidr_blocks_enabled   = true
  additional_cidr_blocks = [
    "10.40.0.0/22",
    "10.30.0.0/22",
    "192.168.31.0/24",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
  ]
}

module "graphql_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  application_family                       = var.application_family
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 8
  task_cpu                                 = 1024
  task_memory                              = var.task_memory
  datadog_task_memory                      = var.datadog_memory
  maximum_capacity                         = 16
  minimum_capacity                         = 8
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      NODE_OPTIONS = "--max-old-space-size=${var.task_memory - var.datadog_memory}"
    },
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      APOLLO_INTROSPECTION = var.introspection
    },
    {
      APOLLO_PLAYGROUND = var.playground
    },
    {
      CACHE_USE_REDIS = "true"
    },
    {
      CACHE_REDIS_HOST = module.elasticache.redis_primary_endpoint_address
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      DD_PROFILING_ENABLED = true
    },
    {
      OWS_SOCIALS_URL = var.ows_socials_url
    },
    {
      OWS_CHARTS_URL = var.ows_charts_url
    },
    {
      OWS_USERS_URL = var.ows_users_url
    },
    {
      NEO4J_URL = var.neo4j_url
    }
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      NEO4J_USER = "${var.environment}/${var.service_name}/NEO4J_USER"
    },
    {
      NEO4J_PASSWORD = "${var.environment}/${var.service_name}/NEO4J_PASSWORD"
    },
    {
      SPLIT_API_KEY = "${var.environment}/${var.service_name}/SPLIT_API_KEY"
    },
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "graphql_analytics_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = "@slack-monitoring @slack-graphql"
  escalation_notification_endpoints = "@slack-monitoring @slack-graphql"
  datadog_service_type              = "${var.service_name}-graphql"
  datadog_service_name              = "graphql.execute"

  service_4xx_monitor_enabled  = true
  service_5xx_monitor_enabled  = true
  critical_number_5xx          = 20
  critical_recovery_number_5xx = 15
  warning_number_5xx           = 10
  warning_recovery_number_5xx  = 5
  critical_number_4xx          = 20
  critical_recovery_number_4xx = 15
  warning_number_4xx           = 10
  warning_recovery_number_4xx  = 5

  dependent_applications = var.dependent_applications
}