module "isni_payload_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  env                = var.environment
  bucket_name        = var.isni_bucket_name
  application_family = var.application_family
  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # only retain payloads for 180 days
  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 180
    }
  ]
}

data "aws_iam_policy_document" "isni_bucket_rw_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
    ]

    resources = [
      "${module.isni_payload_s3_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "isni_bucket_rw_policy" {
  name   = "S3-${var.environment}-isni-payload-bucket-RW"
  policy = data.aws_iam_policy_document.isni_bucket_rw_policy_document.json
  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = true
  }
}