module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  profile = "networking"
  alias   = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/gtm-sonymusicfans/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "main_service" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  datadog_enabled = false

  non_ecr_image                            = "086679231553.dkr.ecr.us-east-1.amazonaws.com/google-tag-manager-wrapper:latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 10
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.this.zone_id
  load_balancer_access_logs_s3_bucket_name = data.aws_s3_bucket.logs.id
  load_balancer_is_internal                = "false"
  vpc_id                                   = module.vpc_info.vpc_id
  health_check_path                        = "/healthz"
  health_check_mode                        = "CMD"
  health_check_command_list                = ["/nodejs/bin/node", "/app/health_checker_bin.js"]
  custom_waf_arn                           = module.custom_waf.waf_blocking_arn_output

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_public_subnet_ids

  prod_https_listener_allow_cidr_blocks = data.cloudflare_ip_ranges.cloudflare.ipv4_cidr_blocks

  environment_variables = [
    { ENVIRONMENT = var.environment },
    { PREVIEW_SERVER_URL = "https://${var.environment}-${local.preview_service_name}.theorchard.io" },
    { HOST = "0.0.0.0" },
  ]
  secrets = [
    { "CONTAINER_CONFIG" = "${var.environment}/${var.service_name}/CONTAINER_CONFIG" }
  ]
}

#Preview must be created after the main service because it depends on the data source of main service's ecs cluster
module "preview_service" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                  = var.environment
  service_name                 = local.preview_service_name
  aws_region                   = var.aws_region
  application_family           = var.application_family
  ecs_cluster_name             = module.main_service.fargate_cluster_name
  secrets_manager_service_name = var.service_name

  datadog_enabled = false

  non_ecr_image             = "086679231553.dkr.ecr.us-east-1.amazonaws.com/google-tag-manager-wrapper:latest"
  container_port            = "8080"
  task_type                 = "web_service"
  desired_task_count        = 1
  task_cpu                  = 512
  task_memory               = 1024
  maximum_capacity          = 1
  minimum_capacity          = 1
  route53_zone_id           = data.aws_route53_zone.this.zone_id
  vpc_id                    = module.vpc_info.vpc_id
  health_check_path         = "/healthz"
  health_check_mode         = "CMD"
  health_check_command_list = ["/nodejs/bin/node", "/app/health_checker_bin.js"]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    { ENVIRONMENT = var.environment },
    { RUN_AS_PREVIEW_SERVER = "true" },
    { HOST = "0.0.0.0" },
  ]
  secrets = [
    { "CONTAINER_CONFIG" = "${var.environment}/${var.service_name}/CONTAINER_CONFIG" }
  ]
}

# Cloudflare records are managed by cloudops team for this domain.

module "service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"

  environment  = var.environment
  service_name = var.service_name

  environment_type                  = "fargate"
  notification_endpoints            = var.alert_channel
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = true
  application_family                = var.application_family
  escalation_notification_endpoints = var.alert_channel
}

output "main_fargate_load_balancer_dns_name" {
  value = module.main_service.fargate_load_balancer_dns_name
}

output "preview_fargate_load_balancer_dns_name" {
  value = module.preview_service.fargate_load_balancer_dns_name
}