provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/iam/application_family/security-tools/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "additional_dynamo_read_policy" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:BatchGetItem",
      "dynamodb:DescribeStream",
      "dynamodb:DescribeTable",
      "dynamodb:GetItem",
      "dynamodb:GetRecords",
      "dynamodb:ListStreams",
      "dynamodb:Query",
      "dynamodb:Scan"
    ]

    resources = [
      "arn:aws:dynamodb:us-east-1:${data.aws_caller_identity.current.account_id}:table/qa-ows-request-authorization",
      "arn:aws:dynamodb:us-east-1:${data.aws_caller_identity.current.account_id}:table/prod-ows-request-authorization"
    ]
  }
}

resource "aws_iam_policy" "additional_dynamo_read_policy" {
  name   = "Dynamo-ows-request-authorization-RO"
  policy = data.aws_iam_policy_document.additional_dynamo_read_policy.json
}

module "abac_policy" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/abac?ref=1.3.2"

  application_family = var.application_family
}

module "rbac_policy" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/rbac?ref=1.3.2"

  application_family = var.application_family
  lambda_functions_or_prefixes_to_access = [
    "*-populate-m2m-jwt-*",
    "*-populate-hfa-*",
    "*-generate-hfa-*",
    "*-create-hfa-*",
    "*-upload-hfa-*",
    "upload-audit-logs-to-s3-*"
  ]
  s3_buckets_or_prefixes_to_access = [
    "qa-orcd-mezzanine-assets",
    "qa-orcd-raw-assets",
    "qa-orcd-video-assets",
    "*-populate-m2m-jwt-lambda-zips",
    "*-orcdbucket/hfa/*",
    "*-orcdbucket/HFA/*",
    "*-upload-audit-logs-to-s3",
    "*-orchard-logging/art_relations/orchadmin_users/*",
    "*-orchard-logging/art_relations/orchadmin_user_roles/*",
    "*-pde-audit-review/quarterly-oa-account-review/*",
    "systems-cloudformation/ows-configs/orchard_repo/*"

  ]
}