provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/iam/groups/business-analysts/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "group_with_attachments" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/groups?ref=1.1.0"

  group_name = "business-analysts"
  users = [
    "agraig",
    "mchar",
    "tallman",
  ]
  application_families_to_access = []
}

#---

data "aws_s3_bucket" "reports_bucket" {
  bucket = "cucumbers"
}

resource "aws_iam_policy" "reports_usage_policy" {
  name   = "S3-prod-cucumbers-bi-reports-usage-policy"
  policy = data.aws_iam_policy_document.reports_usage_policy.json
}

resource "aws_iam_group_policy_attachment" "reports_usage_policy" {
  group      = module.group_with_attachments.iam_group_name
  policy_arn = aws_iam_policy.reports_usage_policy.arn
}

data "aws_iam_policy_document" "reports_usage_policy" {
  statement {
    effect    = "Allow"
    actions   = ["s3:ListBucket"]
    resources = [data.aws_s3_bucket.reports_bucket.arn]

    condition {
      test     = "StringLike"
      variable = "s3:prefix"
      values   = ["BI/reports"]
    }
  }

  statement {
    effect    = "Allow"
    actions   = ["s3:GetObject", "s3:PutObject"]
    resources = ["${data.aws_s3_bucket.reports_bucket.arn}/BI/reports/*"]
  }
}

resource "aws_iam_group_policy_attachment" "s3_dataanalyticsdept_policy_attach" {
  group      = module.group_with_attachments.iam_group_name
  policy_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:policy/S3-dev-dataanalyticsdept-RW"
}