provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/iam/groups/business-cx/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "group_with_attachments" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/groups?ref=1.5.6"

  group_name = "business-cx"
  users = [
    "djones",
  ]
  application_families_to_access = []
}

#---

data "aws_iam_policy_document" "cdn_images_policy_document" {
  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      "arn:aws:s3:::prod-orcd-cdn"
    ]
  }

  statement {
    actions = [
      "s3:List*",
    ]

    resources = [
      "arn:aws:s3:::prod-orcd-cdn/*",
    ]
  }

  statement {
    actions = [
      "s3:AbortMultipartUpload",
      "s3:Get*",
      "s3:List*",
      "s3:PutObject",
      "s3:PutObject*",
    ]

    resources = [
      "arn:aws:s3:::prod-orcd-cdn/images/*",
    ]
  }
}

resource "aws_iam_policy" "cdn_images_policy" {
  name = "S3-prod-orcd-cdn-RO"
  policy = data.aws_iam_policy_document.cdn_images_policy_document.json
}


resource "aws_iam_group_policy_attachment" "cdn_images_policy_attachment" {
  group      = module.group_with_attachments.iam_group_name
  policy_arn = aws_iam_policy.cdn_images_policy.arn
}