provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations 
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/iam/groups/devsec/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "group_with_attachments" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/groups?ref=1.1.0"

  group_name = "devsec"
  users = [
    "mthomas"
  ]
  application_families_to_access = []
}

resource "aws_iam_policy" "access_keys_visibility_policy" {
  name   = "IAM-${var.environment}-devsec-access-keys-visibility-policy"
  policy = data.aws_iam_policy_document.access_keys_visibility_policy.json
}

data "aws_iam_policy_document" "access_keys_visibility_policy" {
  statement {
    effect    = "Allow"
    actions   = ["iam:GetAccessKeyLastUsed", "iam:ListAccessKeys", "iam:GetLoginProfile"]
    resources = ["*"]
  }
}

resource "aws_iam_group_policy_attachment" "access_keys_visibility_policy_attachment" {
  group      = module.group_with_attachments.iam_group_name
  policy_arn = aws_iam_policy.access_keys_visibility_policy.arn
}

resource "aws_iam_policy" "s3_buckets_tags_visibility_policy" {
  name   = "S3-${var.environment}-devsec-s3-buckets-tags-visibility-policy"
  policy = data.aws_iam_policy_document.s3_buckets_tags_visibility_policy.json
}

data "aws_iam_policy_document" "s3_buckets_tags_visibility_policy" {
  statement {
    effect    = "Allow"
    actions   = ["s3:GetBucketTagging"]
    resources = ["*"]
  }
}

resource "aws_iam_group_policy_attachment" "s3_buckets_tags_visibility_policy_attachment" {
  group      = module.group_with_attachments.iam_group_name
  policy_arn = aws_iam_policy.s3_buckets_tags_visibility_policy.arn
}