provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/iam/groups/gsa-analytics/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "group_with_attachments" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/groups?ref=1.22.4"

  group_name = "gsa-analytics"
  users = [
    "mdoeringer",
    "trentschler",
  ]
  application_families_to_access = []
}

#---

data "aws_iam_policy_document" "prod_orcd_ftp_policy_document" {
  statement {
    effect = "Allow"
    actions = ["s3:ListAllMyBuckets"]
    resources = ["*"]
  }

  # Allow navigation through parent folders
  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      "arn:aws:s3:::prod-orcd-ftp"
    ]

    condition {
      test     = "StringEquals"
      variable = "s3:prefix"
      values   = ["", "ftp/", "ftp/QQMedia"]
    }

    condition {
      test     = "StringEquals"
      variable = "s3:delimiter"
      values   = ["/"]
    }
  }

  # Allow listing QQMedia folder contents
  statement {
    actions   = ["s3:ListBucket"]
    resources = ["arn:aws:s3:::prod-orcd-ftp"]

    condition {
      test     = "StringLike"
      variable = "s3:prefix"
      values   = ["ftp/QQMedia/*"]
    }
  }

  # Allow read access to QQMedia folder contents
  statement {
    actions = [
      "s3:Head*",
      "s3:Get*",
      "s3:List*",
    ]

    resources = [
      "arn:aws:s3:::prod-orcd-ftp/ftp/QQMedia/*",
    ]
  }
}

resource "aws_iam_policy" "prod_orcd_ftp_policy" {
  name   = "S3-gsa-analytics-prod-orcd-ftp-policy"
  policy = data.aws_iam_policy_document.prod_orcd_ftp_policy_document.json
}

resource "aws_iam_group_policy_attachment" "prod_orcd_ftp_policy_attachment" {
  group      = module.group_with_attachments.iam_group_name
  policy_arn = aws_iam_policy.prod_orcd_ftp_policy.arn
}