module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ioc-block-list/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "ioc_block_list_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  service_name                      = var.service_name
  application_family                = var.application_family
  aws_region                        = var.region
  commit_sha                        = "latest"
  service_platform_version          = "1.4.0"
  container_port                    = "80"
  task_type                         = "web_service"
  desired_task_count                = 2
  task_cpu                          = 512
  task_memory                       = 1024
  maximum_capacity                  = 2
  minimum_capacity                  = 2
  health_check_path                 = "/"
  health_check_grace_period_seconds = "300"
  container_start_period_seconds    = "300"
  route53_zone_id                   = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  load_balancer_is_internal         = false
  custom_waf_arn                    = "arn:aws:wafv2:us-east-1:437795906767:regional/webacl/prod-public-shared-regional-waf-block/14ab6494-a21c-4066-a93c-bf326727a881"
  prod_https_listener_allow_cidr_blocks = [
    "207.237.185.2/32",
    "208.91.130.130/32",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    }
  ]
}

module "ioc_block_list_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = "devops"
  notification_endpoints            = "@slack-devops"
  escalation_notification_endpoints = "@slack-devops"

  critical_number_5xx          = 20
  critical_recovery_number_5xx = 15
  warning_number_5xx           = 10
  warning_recovery_number_5xx  = 5
}

module "bloxone_multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.bloxone_service_name
  secret_name        = each.value
  application_family = "devops"
}

# Policy document to get bloxone secrets.
data "aws_iam_policy_document" "bloxone_secrets_manager_policy_document" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.bloxone_service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.bloxone_service_name}/*",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

# Assume role policy used by Jenkins pipeline agent role.
data "aws_iam_policy_document" "jenkins_pipeline_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Bloxone secretsmanager policy.
resource "aws_iam_policy" "bloxone_secrets_manager_policy" {
  name   = "Secretsmanager-${var.environment}-${var.bloxone_service_name}-policy"
  policy = data.aws_iam_policy_document.bloxone_secrets_manager_policy_document.json
}

# Jenkins pipeline agents will assume this role in order to get secret
resource "aws_iam_role" "bloxone_service_role" {
  name               = "${var.environment}-${var.bloxone_service_name}-service-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_pipeline_assume_role_policy.json
}

# Attach secretsmanager policy to bloxone service role.
resource "aws_iam_role_policy_attachment" "bloxone_secrets_manager_policy_attachment" {
  role       = aws_iam_role.bloxone_service_role.id
  policy_arn = aws_iam_policy.bloxone_secrets_manager_policy.arn
}