# Assume role policy document used by Jenkins pipeline agent role.
data "aws_iam_policy_document" "jenkins_pipeline_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Jenkins pipeline agents will assume this role in order to update waf ip set.
resource "aws_iam_role" "waf_role" {
  name               = "${var.environment}-${var.service_name}-deployment-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_pipeline_assume_role_policy.json
}

# Policy document for waf ip set.
data "aws_iam_policy_document" "aws_waf_ip_set_policy_document" {
  statement {
    actions = [
      "wafv2:GetIPSet",
      "wafv2:UpdateIPSet",
    ]

    resources = [
      "arn:aws:wafv2:us-east-1:437795906767:regional/ipset/prod-gsirt-ioc-ip-set-ipv6/76672b5e-6d71-4e39-a911-43f15555b463",
      "arn:aws:wafv2:us-east-1:437795906767:regional/ipset/prod-gsirt-ioc-ip-set-ipv4/54e3bbfe-5910-4318-9e58-106a7066e170",
      "arn:aws:wafv2:us-east-1:437795906767:global/ipset/prod-gsirt-ioc-ip-set-ipv6/d827faa5-f9ab-46a9-a458-a93166871379",
      "arn:aws:wafv2:us-east-1:437795906767:global/ipset/prod-gsirt-ioc-ip-set-ipv4/b924f937-4a42-435b-b8ba-c367fdd3e48f",
      "arn:aws:wafv2:us-east-1:437795906767:regional/ipset/gsirt-ioc-ip-set-ipv6/*",
      "arn:aws:wafv2:us-east-1:437795906767:regional/ipset/gsirt-ioc-ip-set-ipv4/*",
      "arn:aws:wafv2:us-east-1:437795906767:global/ipset/gsirt-ioc-ip-set-ipv6/*",
      "arn:aws:wafv2:us-east-1:437795906767:global/ipset/gsirt-ioc-ip-set-ipv4/*",
    ]
  }

  statement {
    actions = [
      "wafv2:ListIPSets",
    ]

    resources = ["*"]
  }
}

resource "aws_iam_policy" "aws_waf_ip_set_policy" {
  name   = "WAF-${var.environment}-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.aws_waf_ip_set_policy_document.json
}

# Attach waf policy to deployment role.
resource "aws_iam_role_policy_attachment" "aws_waf_ip_set_policy_attachment" {
  role       = aws_iam_role.waf_role.id
  policy_arn = aws_iam_policy.aws_waf_ip_set_policy.arn
}