provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/oa-ws/pipeline/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.6"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      for secret in module.secrets : secret.secret_arn
    ]
  }
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
        "arn:aws:iam::086679231553:role/shared-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretManager-${var.environment}-${var.service_name}-RO"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

resource "aws_iam_role" "pipeline_role" {
  name               = "${var.environment}-${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "build_role_secrets_manager_policy_attachment" {
  role       = aws_iam_role.pipeline_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}