provider "aws" {
  region = var.aws_region
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/kafka-infra/debezium_source/art-relations/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "kafka_debezium_source_fargate_environment_art_relations" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment              = var.environment
  service_name             = var.debezium_source_service_name
  application_family       = var.application_family
  additional_tags          = var.additional_tags
  non_ecr_image            = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/kafka-connect-debezium:latest"
  aws_region               = var.aws_region
  service_platform_version = "1.4.0"
  desired_task_count       = 1
  minimum_capacity         = 1
  maximum_capacity         = 2
  task_cpu                 = 2048
  task_memory              = 4096
  container_port           = 8083

  blocking_waf_enabled = true

  health_check_grace_period_seconds = 180
  container_start_period_seconds    = 180
  health_check_path                 = "/connectors/${var.connector_name}"
  web_service_health_check_command  = "[ \"$(curl -s -f http://localhost:8083/connectors/${var.connector_name}/tasks/0/status | jq -r .state)\" == 'RUNNING' ] || exit 1"

  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  route53_zone_id         = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                  = module.vpc_info.vpc_id
  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  https_listener_allow_prefix_list_names = [
    "shared-orcd-jump-box-private-subnet-prefix-list",
  ]
  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = var.debezium_source_service_name
    },
    {
      CONNECTOR_TYPE = "debezium_source"
    },
  ]
  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "art_relations_streams"
    },
    {
      SNAPSHOT_MODE = "no_data"
    },
    {
      SNAPSHOT_LOCKING_MODE = "none"
    },
    {
      DATABASE_HISTORY_KAFKA_TOPIC = "_art_relations_history2"
    },
    {
      DATABASE_SERVER_NAME = var.db_server_name
    },
    {
      DATABASE_TIMEZONE = "UTC"
    },
    {
      DATABASE_SERVER_ID = "201"
    },
    {
      DATABASE_INCLUDE_LIST = "art_relations"
    },
    {
      TABLE_INCLUDE_LIST = join(",", [
        "art_relations.company_brand",
        "art_relations.releases",
        "art_relations.release_territory_restriction",
        "art_relations.subaccount",
        "art_relations.subaccount_royalty_collection",
        "art_relations.subaccount_royalty_collection_territories",
        "art_relations.track",
        "art_relations.track_artist",
        "art_relations.track_audio_attributes",
        "art_relations.track_rights_attributes",
        "art_relations.track_master_rights",
        "art_relations.vendor",
        "art_relations.vendor_contract",
        "art_relations.subaccount_territory_restriction",
        "art_relations.release_artist"
      ])
    },
    {
      SERVICE_NAME = "kafka-connect-debezium-ar"
    },
    {
      SECRETS_MANAGER_DB_KEY = var.db_password_secret_name
    },
    {
      DB_HOST = var.db_host
    },
    {
      DB_PORT = "3306"
    },
    {
      DB_USER = "debezium-ar-src"
    },
    {
      AWS_REGION = "us-east-1"
    },
    {
      TOPIC_CUSTOM_PREFIX = "cdc"
    },
    {
      CHANGE_TOPIC_CASE_FROM = "LOWER_UNDERSCORE"
    },
    {
      CHANGE_TOPIC_CASE_TO = "LOWER_CAMEL"
    }
  ]
}

resource "aws_security_group_rule" "allow_intra_cluster_communication_cr" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_debezium_source_fargate_environment_art_relations.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.13.4"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.debezium_source_service_name
  application_family = var.application_family
  additional_tags    = var.additional_tags
  connector_type     = "debezium_source"

  seconds_behind_source_critical    = 600 # 10 mins
  seconds_behind_source_warning     = 300 # 5 min
  notification_endpoints            = "@slack-kafka-data-highway-alerts"
  escalation_notification_endpoints = "@slack-data-alerts"
  monitor_kafka_topics = [
    "cdc.artRelations.companyBrand",
    "cdc.artRelations.releases",
    "cdc.artRelations.releaseTerritoryRestriction",
    "cdc.artRelations.subaccount",
    "cdc.artRelations.subaccountRoyaltyCollection",
    "cdc.artRelations.subaccountRoyaltyCollectionTerritories",
    "cdc.artRelations.trackMasterRights",
    "cdc.artRelations.track",
    "cdc.artRelations.trackArtist",
    "cdc.artRelations.trackAudioAttributes",
    "cdc.artRelations.trackRightsAttributes",
    "cdc.artRelations.vendor",
    "cdc.artRelations.vendorContract",
    "cdc.artRelations.releaseArtist"
  ]
  monitor_kafka_topics_cluster_name = "prod-managed-kafka-cdc-destination"

  healthy_tasks_monitor_enabled        = true
  service_cpu_monitor_enabled          = true
  error_monitor_enabled                = true
  error_monitor_critical_number_errors = 5
  healthy_tasks_evaluation_window      = "last_15m"

}

module "connector_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment                    = var.environment
  service_name                   = var.debezium_source_service_name
  secret_name                    = var.db_password_secret_name
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}