data "aws_secretsmanager_secret" "datadog_api" {
  name = "${var.environment}/datadog/DD_API_KEY"
}

data "aws_secretsmanager_secret_version" "datadog_api" {
  secret_id = data.aws_secretsmanager_secret.datadog_api.id
}

data "aws_secretsmanager_secret" "datadog_app_key" {
  name = "${var.environment}/datadog/DD_APP_KEY"
}

data "aws_secretsmanager_secret_version" "datadog_app_key" {
  secret_id = data.aws_secretsmanager_secret.datadog_app_key.id
}

# Datadog provider
provider "datadog" {
  api_key = data.aws_secretsmanager_secret_version.datadog_api.secret_string
  app_key = data.aws_secretsmanager_secret_version.datadog_app_key.secret_string
}

resource "datadog_monitor" "kafka_connector_ows_assets_throughput" {
  count   = 1 # set to 0 to disable the monitor
  name    = "${var.environment}-${var.debezium_source_service_name}-throughput-monitor"
  type    = "metric alert"
  message = "Incoming data level has dropped in connector's topics for the last 24h. Notify: ${var.notification_endpoints}"

  query = "sum(last_24h):avg:aws.kafka.messages_in_per_sec{environment:${var.environment},topic:cdc.ows_collaborator.collaborator} * 60 * 60 * 24 <= 0"

  monitor_thresholds {
    critical = 0
    warning  = 3
  }

  notify_no_data      = true
  no_data_timeframe   = 60
  notify_audit        = false
  renotify_interval   = 60
  timeout_h           = 0
  require_full_window = false

  tags = flatten(concat([
    "environment:${var.environment}",
    "service_name:${var.debezium_source_service_name}",
    ],
    [for tag_name, tag_value in var.additional_tags : "${tag_name}:${tag_value}"]
  ))
}