module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = local.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/kafka-infra/jdbc-source/snowflake/create_new_gsrs_from_nmf/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}


module "kafka_jdbc_source_snowflake_create_new_gsrs_from_nmf_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  service_name                      = local.service_name
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.ecr_image_name}:latest"
  application_family                = var.application_family
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 2
  task_cpu                          = 1024
  task_memory                       = 3072
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  container_start_period_seconds    = 180
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${var.connector_name}"
  web_service_health_check_command  = "[ \"$(curl -s -f http://localhost:8083/connectors/${var.connector_name}/tasks/0/status | jq -r .state)\" == 'RUNNING' ] || exit 1"
  propagate_tags                    = true
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  force_new_deployment              = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids
  datadog_custom_image    = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  datadog_task_memory     = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECTOR_TYPE = "default_source"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${local.service_name}"
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      QUERY = replace(templatefile("${path.module}/query.sql", {}), "\n", " ")
    },
    {
      QUOTE_SQL_IDENTIFIERS = "never"
    },
    {
      MODE = "bulk"
    },
    {
      TOPIC_PREFIX = "event.snowflake.newmusicfriday.newtrack"
    },
    {
      POLL_INTERVAL_MS = "600000" # 10 minutes in milliseconds
    },
    {
      BATCH_MAX_ROWS = "10000"
    },
    {
      SNOWFLAKE_CONFIGURATION = "true"
    },
    {
      SNOWFLAKE_SUBDOMAIN = "delphi.us-east-1"
    },
    {
      SNOWFLAKE_WAREHOUSE = "PROD_ETL_WAREHOUSE"
    },
    {
      SNOWFLAKE_DATABASE = "FACTS"
    },
    {
      SNOWFLAKE_ROLE = "PROD_KC_JDBC_SRC_NEW_GSR_NMF_SERVICE_USER_ROLE"
    },
    {
      SNOWFLAKE_SCHEMA = "PROD"
    },
    {
      SNOWFLAKE_USER = "PROD_KC_JDBC_SRC_NEW_GSR_NMF_SERVICE_USER"
    },
    {
      SNOWFLAKE_PRIVATE_KEY_FILENAME = "rsa_key.p8"
    },
    {
      VALIDATE_NON_NULL = "false"
    },
    {
      DEBUG_MODE = "true"
    },
    {
      AWS_SECRETS_MANAGER = "true"
    },
    {
      VALUE_CONVERTER_SCHEMAS_ENABLE = "true"
    },
    {
      TRANSFORMS_VALUE_CONVERTER = "org.apache.kafka.connect.json.JsonConverter"
    },
  ]
  secrets = [
    {
      SNOWFLAKE_PRIVATE_KEY_SECRET = "${var.environment}/${local.service_name}/SNOWFLAKE_PRIVATE_KEY"
    }
  ]
}

module "kafka_create_new_gsrs_from_nmf_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment        = var.environment
  application_family = var.application_family
  service_name       = local.service_name
  secret_name        = "SNOWFLAKE_PRIVATE_KEY"
  additional_tags    = var.additional_tags
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_jdbc_source_snowflake_create_new_gsrs_from_nmf_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "fargate_service_dashboard_create_new_gsrs_from_nmf" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.16.2"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = local.service_name
  connector_type     = "default_source"

  environment_type = "fargate"

  notification_endpoints            = "@slack-data-alerts"
  escalation_notification_endpoints = "@slack-data-alarm"
  monitor_kafka_topics              = ["event.snowflake.newmusicfriday.newtrack"]

  healthy_tasks_monitor_enabled = true
  service_cpu_monitor_enabled   = true
  error_monitor_enabled         = true
}