module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = local.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/kafka-infra/neo4j-cdc-sink/nr-graph/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

module "kafka_neo_sink_nr_graph_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                           = var.environment
  application_family                    = var.application_family
  additional_tags                       = var.additional_tags
  service_name                          = local.service_name
  non_ecr_image                         = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${var.ecr_image_name}:latest"
  aws_region                            = var.aws_region
  service_platform_version              = "1.4.0"
  desired_task_count                    = 1
  minimum_capacity                      = 1
  maximum_capacity                      = 2
  task_cpu                              = 2048
  task_memory                           = 4096
  container_port                        = 8083
  health_check_grace_period_seconds     = 300
  container_start_period_seconds        = 300
  blocking_waf_enabled                  = true
  health_check_path                     = "/connectors/${local.service_name}"
  web_service_health_check_command      = "[[ $(curl -s http://localhost:8083/connectors/${local.service_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  task_placement_failure_alert_enabled  = true
  route53_zone_id                       = data.aws_route53_zone.route53_zone.zone_id
  propagate_tags                        = true

  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory           = 512
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"

  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${local.service_name}"
    },
    {
      CONNECTOR_NAME = local.service_name
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      NEO4J_SERVER_URI = "neo4j+s://e194f55d.databases.neo4j.io"
    },
    {
      NEO4J_DATABASE_NAME = "neo4j"  # Default is graph.db
    },
    {
      NEO4J_KEY_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      NEO4J_VALUE_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      MAX_TASKS = "1"
    },
    {
      NEO4J_KEY_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_VALUE_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_BATCH_SIZE = "1000"
    },
    {
      NEO4J_BATCH_EXEC_TIMEOUT = "15m"
    },
    {
      OFFSET_FLUSH_TIMEOUT = "150000" # msec = 2.5 min
    },
    {
      NEO4J_RETRY_MAX_ATTEMPTS = "2"
    },
    {
      NEO4J_RETRY_TIME = "1m"
    },
    {
      TOPIC_MAPPING_AR_VENDOR = "cdc.artRelations.vendor|${local.ar_vendor}"
    },
    {
      TOPIC_MAPPING_AR_SUBACCOUNT = "cdc.artRelations.subaccount|${local.ar_subaccount}"
    },
    {
      TOPIC_MAPPING_AR_COMPANY_BRAND = "cdc.artRelations.companyBrand|${local.ar_company_brand}"
    },
    {
      DLQ_TOPIC_NAME = "dlq.nrGraph.sink"
    },
    {
      AWS_SECRETS_MANAGER = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      DEBUG_MODE = "true"
    }
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication_nr_graph" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_neo_sink_nr_graph_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "service_credentials_secret" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment                    = var.environment
  application_family             = var.application_family
  additional_tags                = var.additional_tags
  service_name                   = local.service_name
  secret_name                    = "NEO4J_CREDENTIALS"
  secret_recovery_window_in_days = 7
}

module "fargate_service_dashboard_nr_graph" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.13.4"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = local.service_name
  connector_type     = "default_sink"

  environment_type = "fargate"

  notification_endpoints            = "@slack-kafka-data-highway-alerts"
  escalation_notification_endpoints = "@slack-data-alarm"
  healthy_tasks_monitor_enabled     = true
  monitor_kafka_topics = [
    "cdc.artRelations.vendor", "cdc.artRelations.subaccount", "cdc.artRelations.companyBrand", "dlq.nrGraph.sink",
  ]
  monitor_kafka_topics_cluster_name = "prod-managed-kafka-cdc-destination"
  service_cpu_monitor_enabled     = true
  error_monitor_enabled           = true
  dlq_topic_name                  = "dlq.nrGraph.sink"
  healthy_tasks_evaluation_window = "last_15m"
  service_cpu_time_window         = "last_15m"
}