module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/kafka-infra/snowflake-sink/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "snowflake_sink_no_gsr_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  # Shortened to accommodate AWS name length limits
  service_name                      = "${var.service_name}-sfsink-nogsr"
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${var.service_name}-sfsink:latest"
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 2
  task_cpu                          = 2048
  task_memory                       = 4096
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  container_start_period_seconds    = 180
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${local.connector_name_nogsr}"
  web_service_health_check_command  = "[[ $(curl -s http://localhost:8083/connectors/${local.connector_name_nogsr}/status | jq -r '.tasks[].state,.connector.state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  propagate_tags                    = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids
  datadog_custom_image    = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = "${var.service_name}-sfsink-nogsr"
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${var.service_name}-sfsink-nogsr"
    },
    {
      MAX_TASKS = 1
    },
    {
      BUFFER_COUNT_RECORDS = 10000
    },
    {
      BUFFER_SIZE_BYTES = 5000000
    },
    {
      BUFFER_FLUSH_TIME = 240
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      CONNECTOR_NAME = local.connector_name_nogsr
    },

    {
      SNOWFLAKE_INGESTION_METHOD = "SNOWPIPE_STREAMING"
    },
    {
      SNOWFLAKE_HOST = "delphi.us-east-1.snowflakecomputing.com:443"
    },
    {
      SNOWFLAKE_USER = "PROD_KAFKA_CONNECT"
    },
    {
      SNOWFLAKE_DATABASE = "FACTS"
    },
    {
      SNOWFLAKE_SCHEMA = "PROD"
    },
    {
      SNOWFLAKE_ROLE = "FACTS_DB_PROD_SCHEMA_READWRITE"
    },
    {
      SERVICE_NAME = "${var.service_name}-sfsink-nogsr"
    },
    {
      KAFKA_TOPICS = join(",", [
        "event.musicEvent.socialMedia",
        "event.orchardSoundRecording.delivery",
        "event.owsAssets.acrCloudAudioInfringements",
        "event.spotifyapi.audioFeatures",
        "event.spotifyapi.audioFeatures.missing",
        "event.spotifyapi.album.artist",
        "event.spotifyapi.track.artist",
        "stream.acousticBrainz.audioFeatures"
      ])
    },
    {
      SNOWFLAKE_TOPIC_TABLE_MAP = join(",", [
        "event.musicEvent.socialMedia:EVENT_MUSIC_EVENT_SOCIAL_MEDIA",
        "event.orchardSoundRecording.delivery:EVENT_ORCHARD_SOUND_RECORDING_DELIVERY",
        "event.owsAssets.acrCloudAudioInfringements:EVENT_OWS_ASSETS_ACRCLOUD_AUDIO_INFRINGEMENTS",
        "event.spotifyapi.audioFeatures:EVENT_SPOTIFY_API_AUDIO_FEATURES",
        "event.spotifyapi.audioFeatures.missing:EVENT_SPOTIFY_API_AUDIO_FEATURES_MISSING",
        "event.spotifyapi.album.artist:EVENT_SPOTIFY_API_ALBUM_ARTIST",
        "event.spotifyapi.track.artist:EVENT_SPOTIFY_API_TRACK_ARTIST",
        "stream.acousticBrainz.audioFeatures:STREAM_ACOUSTIC_BRAINZ_AUDIO_FEATURES"
      ])
    },
    {
      DLQ_TOPIC_NAME = "dlq.snowflakeSink.noGSR"
    },
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication_no_gsr" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.snowflake_sink_no_gsr_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "fargate_service_dashboard_no_gsr" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.13.4"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  environment_type   = "fargate"
  service_name       = "${var.service_name}-sfsink-nogsr"
  connector_type     = "default_sink"

  notification_endpoints            = "@slack-kafka-data-highway-alerts"
  escalation_notification_endpoints = "@slack-data"
  monitor_kafka_topics_cluster_name = var.kafka_cluster_name
  monitor_kafka_topics = [
    "event.musicEvent.socialMedia",
    "event.orchardSoundRecording.delivery",
    "event.owsAssets.acrCloudAudioInfringements",
    "event.spotifyapi.audioFeatures",
    "event.spotifyapi.audioFeatures.missing",
    "event.spotifyapi.album.artist",
    "event.spotifyapi.track.artist",
    "stream.acousticBrainz.audioFeatures"
  ]

  healthy_tasks_monitor_enabled        = true
  service_cpu_monitor_enabled          = true
  error_monitor_enabled                = true
  error_monitor_critical_number_errors = 5
  dlq_topic_name                       = "dlq.snowflakeSink.noGSR"
}