module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = local.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/kafka-infra/snowflake-sink-artist-diy/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

# GDA failure events monitor
resource "datadog_monitor" "gda-failures-monitor" {
  name               = "${var.environment}-${local.service_name}-failures-monitor"
  type               = "query alert"
  message            = "Audit gda failure events alarm triggered. Notify: ${var.notification_endpoints}"
  escalation_message = "GDA event is still producing errors. Escalation to ${var.escalation_notification_endpoints}"

  query = "avg(last_1h):avg:aws.kafka.messages_in_per_sec{environment:${var.environment},topic:dlq.gda*} by {topic} >= 1"

  monitor_thresholds {
    critical = 1
  }

  include_tags        = true
  notify_no_data      = false
  no_data_timeframe   = 15
  notify_audit        = false
  renotify_interval   = 60
  timeout_h           = 0
  require_full_window = false

  tags = [
    "environment:${var.environment}",
    "service_name:${local.service_name}",
  ]
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "snowflake_sink_gda_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.5.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  # Shortened to accommodate AWS name length limits
  service_name                      = local.service_name
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.ecr_image_name}:latest"
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 2
  task_cpu                          = 1024
  task_memory                       = 3072
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  container_start_period_seconds    = 180
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${var.connector_name}"
  web_service_health_check_command  = "[[ $(curl -s http://localhost:8083/connectors/${var.connector_name}/status | jq -r '.tasks[].state,.connector.state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  vpc_id                            = module.vpc_info.vpc_id
  https_listener_certificate_id     = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  propagate_tags                    = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids
  datadog_custom_image  = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = local.ecs_cluster_name
    },
    {
      MAX_TASKS = 1
    },
    {
      BUFFER_COUNT_RECORDS = 10000
    },
    {
      BUFFER_SIZE_BYTES = 5000000
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      SNOWFLAKE_HOST = "delphi.us-east-1.snowflakecomputing.com:443"
    },
    {
      SNOWFLAKE_USER = "PROD_KAFKA_CONNECT"
    },
    {
      SNOWFLAKE_DATABASE = "FACTS"
    },
    {
      SNOWFLAKE_SCHEMA = "PROD"
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      KAFKA_TOPICS = join(",", [
        "event.gdaSubmitApplication",
        "event.gdaSignup",
        "event.gdaApproval",
        "event.gdaLeads",
        "event.gdaUnqualifiedLeads",
        "event.gda.redeemVoucher",
        "dlq.gdaSignup",
      ])
    },
    {
      SNOWFLAKE_TOPIC_TABLE_MAP = join(",", [
        "event.gdaSubmitApplication:AUDIT_EVENT_GDA_SUBMIT_APPLICATION",
        "event.gdaSignup:AUDIT_EVENT_GDA_SIGNUP",
        "event.gdaApproval:AUDIT_EVENT_GDA_APPROVAL",
        "event.gdaLeads:AUDIT_EVENT_GDA_LEADS",
        "event.gdaUnqualifiedLeads:AUDIT_EVENT_GDA_UNQUALIFIED_LEADS",
        "event.gda.redeemVoucher:AUDIT_EVENT_GDA_REDEEM_VOUCHER",
        "dlq.gdaSignup:AUDIT_DLQ_GDA_SIGNUP",
      ])
    }
  ]
}
resource "aws_security_group_rule" "allow_intra_cluster_communication_gda" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.snowflake_sink_gda_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.13.4"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  environment_type   = "fargate"
  service_name       = local.service_name
  connector_type     = "default_sink"

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
  monitor_kafka_topics_cluster_name = "prod-managed-kafka-artist-diy"
  monitor_kafka_topics = [
    "event.gdaSubmitApplication",
    "event.gdaSignup",
    "event.gdaApproval",
    "event.gdaLeads",
    "event.gdaUnqualifiedLeads",
    "event.gda.redeemVoucher",
    "event.gdaAccountCreation.success",
    "dlq.gdaSignup",
  ]

  healthy_tasks_monitor_enabled = true
  service_cpu_monitor_enabled   = true
  error_monitor_enabled         = true
  dlq_topic_name                = "dlq.gdaSignup"

}

module "gda_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  application_family             = var.application_family
  additional_tags                = var.additional_tags
  service_name                   = local.service_name
  secret_name                    = each.value
  secret_recovery_window_in_days = 7
}