provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/kollectivenr/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_kinesis_firehose_delivery_stream" "stream" {
  name = "aws-waf-logs-tf-orcd-prod-stream"
}

resource "aws_acm_certificate" "tls_cert" {
  # checkov:skip=CKV2_AWS_71: Ensure AWS ACM Certificate domain name does not include wildcards
  domain_name               = "*.${var.domain_name}"
  subject_alternative_names = [var.domain_name]
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn         = aws_acm_certificate.tls_cert.arn

  timeouts {
    create = "2h"
  }
}

# Add WAF for Cloudfront distributions
module "cloudfront_waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=2.0.0"
  environment       = var.environment
  service_name      = var.service_name
  aws_region        = var.aws_region
  acl_scope         = "CLOUDFRONT"
  count_waf_enabled = false
  block_waf_enabled = true
}