data "aws_iam_policy" "abacus_adjustments_usage_policy" {
  name   = "S3-${var.environment}-abacus-adjustments-usage-policy"
}

locals {
  lambda_abacus_adjustment_file_import_service_name = "${var.service_name}-adjustment-file-import"
  lambda_abacus_adjustment_file_import_maximum_duration = 840000
}

module "lambda_abacus_adjustment_file_import_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = local.lambda_abacus_adjustment_file_import_service_name
  teams               = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_abacus_adjustment_file_import_owsrequest" {
  source             = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"
  environment_name   = var.environment
  service_name       = local.lambda_abacus_adjustment_file_import_service_name
}

module "lambda_abacus_adjustment_file_import" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Import adjustment file content."
  lambda_name                                       = "lambda-abacus-adjustment-file-import"
  vpc_id                                            = var.vpc_id
  vpc_subnet_ids                                    = var.vpc_subnet_ids
  application_family                                = var.application_family
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 16
  lambda_function_memory_size                    = 10240

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT            = var.environment
    MYSQL_DB_NAME          = var.lambda_abacus_mysql_database
    MYSQL_DB_HOST          = var.lambda_abacus_mysql_host
    MYSQL_DB_USER          = var.lambda_abacus_mysql_user
    S3_BUCKET_NAME         = var.abacus_adjustments_bucket_name
  }

  iam_managed_policy_attachments = [
    module.lambda_abacus_adjustment_file_import_owsrequest.policy_arn_output,
    data.aws_iam_policy.abacus_adjustments_usage_policy.arn
  ]
}

module "lambda_abacus_adjustment_file_import_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = local.lambda_abacus_adjustment_file_import_service_name
  secret_name        = each.value
}

module "datadog_lambda_abacus_adjustment_file_import" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.10.7"

  environment                         = var.environment
  service_name                        = local.lambda_abacus_adjustment_file_import_service_name
  notification_endpoints              = "${var.notification_endpoints} ${var.escalation_notification_endpoints} ${var.on_call_endpoint}"
  escalation_notification_endpoints   = "${var.notification_endpoints} ${var.escalation_notification_endpoints} ${var.on_call_endpoint}"

  lambda_error_critical_number          = 0.2
  lambda_error_critical_recovery_number = 0

  lambda_error_warning_number          = 0.1
  lambda_error_warning_recovery_number = 0
}

resource "datadog_monitor" "datadog_lambda_abacus_adjustment_file_import_duration_monitor" {
  name = "${var.environment}-${local.lambda_abacus_adjustment_file_import_service_name}-duration-monitor"
  type = "query alert"
  message = "Monitor triggered. Notify: ${var.notification_endpoints} ${var.escalation_notification_endpoints} ${var.on_call_endpoint}"

  query = "max(last_15m):max:aws.lambda.duration{environment:${var.environment}, service_name:${local.lambda_abacus_adjustment_file_import_service_name}} >= ${local.lambda_abacus_adjustment_file_import_maximum_duration}"


  monitor_thresholds {
    critical = local.lambda_abacus_adjustment_file_import_maximum_duration
  }

  tags = [
    "environment:${var.environment}",
    "service_name:${local.lambda_abacus_adjustment_file_import_maximum_duration}",
    "application_family:${var.application_family}"
  ]

  evaluation_delay = 900
  include_tags = true
  notify_no_data = false
  notify_audit = false
  renotify_interval = 0
  renotify_occurrences = 0
  require_full_window = false
  timeout_h = 0
}

module "m2m_secrets_adjustment_file_import" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment                         = var.environment
  service_name                        = "${var.service_name}-adjustment-file-import"
  application_family                  = var.application_family
}