locals {
  json_import_lambda_name = "${var.service_name}-adjustments-json-import"
  json_import_lambda_max_duration = 900000
}

module "lambda_abacus_adjustments_json_import_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  platform           = "python"
  service_name       = "${var.service_name}-adjustments-json-import"
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

data "aws_iam_policy" "s3_abacus_adjustments_json_import_usage_policy" {
  name = "S3-${var.environment}-abacus-adjustments-usage-policy"
}

module "lambda_abacus_adjustments_json_import" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Read and process the JSON file to import multiple adjustment records."
  lambda_name                                       = local.json_import_lambda_name
  vpc_id                                            = var.vpc_id

  vpc_subnet_ids                                    = var.vpc_subnet_ids
  application_family                                = var.application_family
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 2
  lambda_function_memory_size                      = 10240

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT         = var.environment
    SENTRY_DSN          = module.lambda_abacus_adjustments_json_import_sentry_project.sentry_key_dsn_public_output

    MYSQL_DB_NAME  = var.lambda_abacus_mysql_database
    MYSQL_DB_HOST  = var.lambda_abacus_mysql_host
    MYSQL_DB_USER  = var.lambda_abacus_mysql_user
    S3_BUCKET_NAME = var.abacus_adjustments_bucket_name
  }

  iam_managed_policy_attachments = [
    data.aws_iam_policy.s3_abacus_adjustments_json_import_usage_policy.arn
  ]
}

module "lambda_abacus_adjustments_json_import_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.adjustments_json_import_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = "${var.service_name}-adjustments-json-import"
  secret_name        = each.value
}

module "lambda_abacus_adjustments_json_import_datadog_monitor" {
  source                                = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.17.1"
  service_name                          = local.json_import_lambda_name
  environment                           = var.environment
  lambda_invocation_monitor_enabled     = false
  lambda_error_monitor_enabled          = true
  lambda_error_critical_number          = 1
  lambda_error_ok_number                = 0
  lambda_error_warning_recovery_number  = null
  lambda_error_critical_recovery_number = null
  lambda_error_warning_number           = null
  notification_endpoints                = var.notification_endpoints
}

resource "datadog_monitor" "lambda_abacus_adjustments_json_import_duration_datadog_monitor" {
  name = "${var.environment}-${local.json_import_lambda_name}-duration-monitor"
  type = "query alert"
  message = "Monitor triggered. Notify: ${var.notification_endpoints}"

  query = "max(last_15m):max:aws.lambda.duration{environment:${var.environment}, service_name:${local.json_import_lambda_name}} >= ${local.json_import_lambda_max_duration}"

  monitor_thresholds {
    critical = local.json_import_lambda_max_duration
  }

  evaluation_delay = 900
  include_tags = true
  notify_no_data = false
  notify_audit = false
  renotify_interval = 0
  renotify_occurrences = 0
  require_full_window = false
  timeout_h = 0


  tags = [
    "environment:${var.environment}",
    "service_name:${local.json_import_lambda_name}",
    "application_family:${var.application_family}",
    "team:abacus-${var.environment}",
  ]
}