locals {
  flowthrough_generate_lambda_name = "${var.service_name}-generate-flowthrough-adjustments"
  flowthrough_generate_lambda_max_duration = 900000
}

module "lambda_abacus_generate_flowthrough_adjustments_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  platform           = "python"
  service_name       = "${var.service_name}-generate-flowthrough-adjs"
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_abacus_generate_flowthrough_adjustments_owsrequest" {
  source             = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  environment_name   = var.environment
  service_name       = "${var.service_name}-generate-flowthrough-adjustments"
}

data "aws_iam_policy" "s3_abacus_adjustments_usage_policy" {
  name = "S3-${var.environment}-abacus-adjustments-usage-policy"
}

module "lambda_abacus_generate_flowthrough_adjustments" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.2"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Auto generate flowthrough adjustments."
  lambda_name                                       = local.flowthrough_generate_lambda_name
  vpc_id                                            = var.vpc_id

  vpc_subnet_ids                                    = var.vpc_subnet_ids
  application_family                                = var.application_family
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 2
  lambda_function_memory_size                      = 10240

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT         = var.environment
    SENTRY_DSN          = module.lambda_abacus_generate_flowthrough_adjustments_sentry_project.sentry_key_dsn_public_output

    SNOWFLAKE_ACCOUNT   = var.lambda_snowflake_account
    SNOWFLAKE_DATABASE  = var.lambda_snowflake_orchard_app_database
    SNOWFLAKE_SCHEMA    = var.lambda_snowflake_schema
    SNOWFLAKE_WAREHOUSE = var.lambda_dbt_warehouse
    SNOWFLAKE_ROLE      = var.lambda_dbt_role
    SNOWFLAKE_USER      = var.lambda_snowflake_user
    S3_BUCKET_NAME      = var.abacus_adjustments_bucket_name
    FIVETRAN_SCHEMA     = var.fivetran_schema
  }

  iam_managed_policy_attachments = [
    module.lambda_abacus_generate_flowthrough_adjustments_owsrequest.policy_arn_output,
    data.aws_iam_policy.s3_abacus_adjustments_usage_policy.arn
  ]
}

module "lambda_abacus_generate_flowthrough_adjustments_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = "${var.service_name}-generate-flowthrough-adjustments"
  secret_name        = each.value
}

module "lambda_abacus_generate_flowthrough_adjustments_datadog_monitor" {
  source                                = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.17.1"
  service_name                          = local.flowthrough_generate_lambda_name
  environment                           = var.environment
  lambda_invocation_monitor_enabled     = false
  lambda_error_monitor_enabled          = true
  lambda_error_critical_number          = 1
  lambda_error_ok_number                = 0
  lambda_error_warning_recovery_number  = null
  lambda_error_critical_recovery_number = null
  lambda_error_warning_number           = null
  notification_endpoints                = var.notification_endpoints
}

resource "datadog_monitor" "lambda_abacus_generate_flowthrough_adjustments_duration_datadog_monitor" {
  name = "${var.environment}-${local.flowthrough_generate_lambda_name}-duration-monitor"
  type = "query alert"
  message = "Monitor triggered. Notify: ${var.notification_endpoints}"

  query = "max(last_15m):max:aws.lambda.duration{environment:${var.environment}, service_name:${local.flowthrough_generate_lambda_name}} >= ${local.flowthrough_generate_lambda_max_duration}"

  monitor_thresholds {
    critical = local.flowthrough_generate_lambda_max_duration
  }

  evaluation_delay = 900
  include_tags = true
  notify_no_data = false
  notify_audit = false
  renotify_interval = 0
  renotify_occurrences = 0
  require_full_window = false
  timeout_h = 0


  tags = [
    "environment:${var.environment}",
    "service_name:${local.flowthrough_generate_lambda_name}",
    "application_family:${var.application_family}",
    "team:abacus-${var.environment}",
  ]
}