locals {
  payment_allocation_lambda_name         = "${var.service_name}-payment-allocation"
  payment_allocation_lambda_max_duration = 900000
}

module "lambda_abacus_payment_allocation_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  platform           = "python"
  service_name       = local.payment_allocation_lambda_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_abacus_payment_allocation_owsrequest" {
  source           = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  environment_name = var.environment
  service_name     = local.payment_allocation_lambda_name
}

module "lambda_abacus_payment_allocation" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment               = var.environment
  lambda_function_timeout   = 900
  use_container_image       = true
  lambda_description        = "Allocate payments for flowthrough contracts."
  lambda_name               = local.payment_allocation_lambda_name
  vpc_id                    = var.vpc_id
  vpc_subnet_ids            = var.vpc_subnet_ids
  vpc_create_security_group = true
  application_family        = var.application_family
  # lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  # lambda_function_reserved_concurrent_executions = 2
  lambda_function_memory_size = 10240

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment

    MYSQL_DB_HOST = var.lambda_abacus_mysql_host
    MYSQL_DB_NAME = var.lambda_abacus_mysql_database
    MYSQL_DB_USER = var.lambda_abacus_mysql_user
  }

  iam_managed_policy_attachments = [
    module.lambda_abacus_payment_allocation_owsrequest.policy_arn_output
  ]
}

#######################################
## EventBridge Close Balance Trigger ##
#######################################

# EventBridge rule to trigger payment allocation on close_balance.completed
resource "aws_cloudwatch_event_rule" "payment_allocation_close_balance" {
  name        = "${var.environment}-${local.payment_allocation_lambda_name}-close-balance"
  description = "Trigger payment allocation when close_balance completes"

  event_pattern = jsonencode({
    source      = ["abacus.outbox"]
    detail-type = ["close_balance.completed"]
  })

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = local.payment_allocation_lambda_name
    teams              = "abacus-${var.environment}"
    terraformed        = true
  }
}

# EventBridge target to invoke payment allocation Lambda
resource "aws_cloudwatch_event_target" "payment_allocation_close_balance" {
  rule      = aws_cloudwatch_event_rule.payment_allocation_close_balance.name
  target_id = "PaymentAllocationLambda"
  arn       = module.lambda_abacus_payment_allocation.lambda_arn
}

# Permission for EventBridge to invoke Lambda
resource "aws_lambda_permission" "allow_eventbridge_payment_allocation" {
  statement_id  = "AllowExecutionFromEventBridge"
  action        = "lambda:InvokeFunction"
  function_name = module.lambda_abacus_payment_allocation.lambda_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.payment_allocation_close_balance.arn
}

########################
## Secrets Management ##
########################

module "lambda_abacus_payment_allocation_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.payment_allocation_secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = local.payment_allocation_lambda_name
  secret_name        = each.value
}

module "lambda_abacus_payment_allocation_datadog_monitor" {
  source                                = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.17.1"
  service_name                          = local.payment_allocation_lambda_name
  environment                           = var.environment
  lambda_invocation_monitor_enabled     = false
  lambda_error_monitor_enabled          = true
  lambda_error_critical_number          = 1
  lambda_error_ok_number                = 0
  lambda_error_warning_recovery_number  = null
  lambda_error_critical_recovery_number = null
  lambda_error_warning_number           = null
  notification_endpoints                = var.notification_endpoints
}

resource "datadog_monitor" "lambda_abacus_payment_allocation_duration_datadog_monitor" {
  name    = "${var.environment}-${local.payment_allocation_lambda_name}-duration-monitor"
  type    = "query alert"
  message = "Monitor triggered. Notify: ${var.notification_endpoints}"

  query = "max(last_15m):max:aws.lambda.duration{environment:${var.environment}, service_name:${local.payment_allocation_lambda_name}} >= ${local.payment_allocation_lambda_max_duration}"

  monitor_thresholds {
    critical = local.payment_allocation_lambda_max_duration
  }

  evaluation_delay     = 900
  include_tags         = true
  notify_no_data       = false
  notify_audit         = false
  renotify_interval    = 0
  renotify_occurrences = 0
  require_full_window  = false
  timeout_h            = 0

  tags = [
    "environment:${var.environment}",
    "service_name:${local.payment_allocation_lambda_name}",
    "application_family:${var.application_family}",
    "team:abacus-${var.environment}",
  ]
}