locals {
  sync_account_lambda_name = "${var.service_name}-sync-account"
}

module "lambda_abacus_sync_account_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = local.sync_account_lambda_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_abacus_sync_account" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Creates/updates ABACUS account"
  lambda_name                                       = local.sync_account_lambda_name
  vpc_id                                            = var.vpc_id
  vpc_subnet_ids                                    = var.vpc_subnet_ids
  application_family                                = var.application_family
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 200
  lambda_function_memory_size                    = 1024

  lambda_function_environment_variables = {
    ENVIRONMENT         = var.environment
    GRAPHQL_GATEWAY_URL = var.graphql_url
  }

  msk_event_enabled                          = true
  event_source_mapping_msk_cluster_name      = var.trigger_msk_artist_diy_cluster_name
  event_source_mapping_msk_cluster_uuid      = var.trigger_msk_artist_diy_cluster_uuid
  event_source_mapping_batch_size            = 1
  msk_topics                                 = [var.accounts_topic]
  event_source_mapping_starting_position     = "LATEST"
  datadog_advanced_merge_xray_traces_enabled = false
}

module "lambda_abacus_sync_account_add_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.sync_account_secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = "${var.service_name}-sync-account"
  secret_name        = each.value
}


module "lambda_abacus_sync_account_datadog_monitor" {
  source                                = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.10.7"
  service_name                          = local.sync_account_lambda_name
  environment                           = var.environment
  lambda_invocation_monitor_enabled     = false
  lambda_error_monitor_enabled          = true
  lambda_error_critical_number          = 1
  lambda_error_ok_number                = 0
  lambda_error_warning_recovery_number  = null
  lambda_error_critical_recovery_number = null
  lambda_error_warning_number           = null
  notification_endpoints                = var.notification_endpoints
  teams                                 = var.teams
}