provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/lambda-audience/export-audience-file/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_caller_identity" "current" {}

module "lambda_export_audience_file" {
  source                      = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"
  lambda_name                 = var.lambda_name
  lambda_description          = "Lambda to handle audience export to file."
  lambda_function_timeout     = var.lambda_timeout
  lambda_function_memory_size = var.lambda_memory_size
  environment                 = var.environment
  application_family          = var.application_family

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids

  use_container_image = true

  datadog_advanced_enabled = true

  lambda_function_ephemeral_storage_size = var.lambda_ephemeral_storage_size

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    SENTRY_DSN  = module.lambda_export_audience_file_sentry.sentry_key_dsn_public_output
  }

  iam_managed_policy_attachments = [
    data.aws_iam_policy.audience_export_s3_policy.arn
  ]
}

module "lambda_export_audience_file_sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "lambda_export_audience_file_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false

  lambda_error_ok_number                = 0
  lambda_error_warning_number           = 2
  lambda_error_warning_recovery_number  = 0
  lambda_error_critical_number          = 3
  lambda_error_critical_recovery_number = 2

  notification_endpoints            = "@slack-fansifter-alerts @oncall-fansifter"
  escalation_notification_endpoints = "@slack-fansifter"
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.lambda_name
  application_family = var.application_family
}