locals {
  acrcloud_audio_infringements_lambda_name = "${var.service_name}-acrcloud-audio-infringements"
}

module "lambda_content_acrcloud_audio_infringements_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"

  environment_name = var.environment
  service_name     = local.acrcloud_audio_infringements_lambda_name
}

module "lambda_content_acrcloud_audio_infringements" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.acrcloud_audio_infringements_lambda_name

  use_container_image      = true
  lambda_description       = "Send Acrcloud audio infringement data from approved products to snowflake"
  lambda_function_timeout  = "60"
  vpc_enabled              = true
  vpc_id                   = var.vpc_id
  vpc_subnet_ids           = var.vpc_subnet_ids
  datadog_enabled          = true
  datadog_advanced_enabled = true
  additional_tags          = var.additional_tags

  lambda_function_environment_variables = {
    ENVIRONMENT                            = var.environment
    SENTRY_DSN                             = module.sentry_lambda_content_acrcloud_audio_infringements.sentry_key_dsn_public_output
    ACRCLOUD_AUDIO_INFRINGEMENTS_MSK_TOPIC = var.acrcloud_audio_infringements_msk_topic
    KAFKA_BOOTSTRAP_SERVERS                = var.kafka_bootstrap_servers
  }

  msk_event_enabled                      = true
  event_source_mapping_msk_cluster_name  = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid  = var.trigger_msk_cluster_uuid
  event_source_mapping_batch_size        = 1
  kafka_topics                           = [var.product_review_msk_topic]
  event_source_mapping_starting_position = "LATEST"
  event_source_mapping_filter_criteria_pattern = jsonencode({ "value" : { "operation" : { "context": ["approve"] } } })

  iam_managed_policy_attachments = [
    module.lambda_content_acrcloud_audio_infringements_owsrequest.policy_arn_output,
    aws_iam_policy.acrcloud_audio_infringements_msk_produce_policy.arn,
  ]
}

# stage datadog creds and create dashboards.
module "datadog_lambda_content_acrcloud_audio_infringements" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = local.acrcloud_audio_infringements_lambda_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

module "sentry_lambda_content_acrcloud_audio_infringements" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = local.acrcloud_audio_infringements_lambda_name
  application_family = var.application_family
}

data "aws_iam_policy_document" "acrcloud_audio_infringements_msk_produce_policy" {
  statement {
    effect  = "Allow"
    actions = ["kafka-cluster:Connect"]
    resources = [
      "arn:aws:kafka:${var.aws_region}:${data.aws_caller_identity.current.account_id}:cluster/${var.trigger_msk_cluster_name}/${var.trigger_msk_cluster_uuid}",
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "kafka-cluster:DescribeTopic",
      "kafka-cluster:WriteData",
    ]
    resources = [
      "arn:aws:kafka:${var.aws_region}:${data.aws_caller_identity.current.account_id}:topic/${var.trigger_msk_cluster_name}/${var.trigger_msk_cluster_uuid}/${var.acrcloud_audio_infringements_msk_topic}",
    ]
  }
}

resource "aws_iam_policy" "acrcloud_audio_infringements_msk_produce_policy" {
  name   = "${var.environment}-${local.acrcloud_audio_infringements_lambda_name}-msk-produce"
  policy = data.aws_iam_policy_document.acrcloud_audio_infringements_msk_produce_policy.json
}