locals {
  lambda_content_asgv_evaluate_results = "${var.service_name}-asgv-evaluate-results"
}

module "lambda_content_asgv_evaluate_results" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.lambda_content_asgv_evaluate_results

  use_container_image                            = true
  lambda_description                             = "Evaluates the Apple Style Guide Validator Bedrock output, scoring each rule by weight and producing a structured report persisted to S3."
  lambda_function_timeout                        = "60"
  vpc_enabled                                    = true
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  datadog_enabled                                = true
  datadog_advanced_enabled                       = true

  lambda_function_environment_variables = {
    ENVIRONMENT           = var.environment
    SENTRY_DSN            = module.sentry_lambda_content_asgv_evaluate_results.sentry_key_dsn_public_output
    EXPECTED_BUCKET_OWNER = data.aws_caller_identity.current.account_id
    RESULTS_BUCKET        = module.apple_sg_validator_results_bucket.s3_bucket_name_output
    RESULTS_BUCKET_PREFIX = var.results_bucket_prefix
  }

  datadog_advanced_merge_xray_traces_enabled = false
}

data "aws_iam_policy_document" "asgv_evaluate_results_s3" {
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.apple_sg_validator_results_bucket.s3_bucket_arn_output}/${var.bedrock_model_output_prefix}*",
    ]
  }

  statement {
    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.apple_sg_validator_results_bucket.s3_bucket_arn_output}/${var.results_bucket_prefix}*",
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
    ]

    resources = [
      module.apple_sg_validator_results_bucket.s3_bucket_arn_output,
    ]
  }
}

resource "aws_iam_policy" "asgv_evaluate_results_s3" {
  name   = "S3-${var.environment}-${local.lambda_content_asgv_evaluate_results}-RW"
  policy = data.aws_iam_policy_document.asgv_evaluate_results_s3.json
}

resource "aws_iam_role_policy_attachment" "asgv_evaluate_results_s3" {
  role       = module.lambda_content_asgv_evaluate_results.lambda_role_id
  policy_arn = aws_iam_policy.asgv_evaluate_results_s3.arn
}

module "datadog_lambda_content_asgv_evaluate_results" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.15.3"

  environment                       = var.environment
  service_name                      = local.lambda_content_asgv_evaluate_results
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

module "sentry_lambda_content_asgv_evaluate_results" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = local.lambda_content_asgv_evaluate_results
  application_family = var.application_family
}