locals {
  lambda_content_asgv_prepare_payload = "${var.service_name}-asgv-prepare-payload"
}

module "lambda_content_asgv_prepare_payload" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.lambda_content_asgv_prepare_payload

  use_container_image                            = true
  lambda_description                             = "Prepares the payload for the Apple Style Guide Validator step function, by fetching necessary metadata and transforming it into the expected format."
  lambda_function_timeout                        = "60"
  vpc_enabled                                    = true
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  datadog_enabled                                = true
  datadog_advanced_enabled                       = true

  lambda_function_environment_variables = {
    ENVIRONMENT           = var.environment
    SENTRY_DSN            = module.sentry_lambda_content_asgv_prepare_payload.sentry_key_dsn_public_output
    EXPECTED_BUCKET_OWNER = data.aws_caller_identity.current.account_id
  }

  datadog_advanced_merge_xray_traces_enabled = false
}

data "aws_s3_bucket" "content_auto_approve_product_snapshots" {
  bucket = "${var.environment}-content-auto-approve-product-snapshots"
}

data "aws_iam_policy_document" "asgv_prepare_payload_s3_read" {
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${data.aws_s3_bucket.content_auto_approve_product_snapshots.arn}/*",
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
    ]

    resources = [
      data.aws_s3_bucket.content_auto_approve_product_snapshots.arn,
    ]
  }
}

resource "aws_iam_policy" "asgv_prepare_payload_s3_read" {
  name   = "S3-${var.environment}-${local.lambda_content_asgv_prepare_payload}-RO"
  policy = data.aws_iam_policy_document.asgv_prepare_payload_s3_read.json
}

resource "aws_iam_role_policy_attachment" "asgv_prepare_payload_s3_read" {
  role       = module.lambda_content_asgv_prepare_payload.lambda_role_id
  policy_arn = aws_iam_policy.asgv_prepare_payload_s3_read.arn
}

module "datadog_lambda_content_asgv_prepare_payload" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.15.3"

  environment                       = var.environment
  service_name                      = local.lambda_content_asgv_prepare_payload
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

module "sentry_lambda_content_asgv_prepare_payload" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = local.lambda_content_asgv_prepare_payload
  application_family = var.application_family
}