data "aws_iam_policy_document" "reindex_product_metadata_invoke_policy" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
      "lambda:GetFunction",
      "lambda:GetFunctionConfiguration",
      "lambda:GetPolicy",
      "lambda:GetAlias",
      "lambda:ListVersionsByFunction",
      "lambda:ListAliases",
      "lambda:GetFunctionEventInvokeConfig"
    ]
    resources = [
      module.lambda_content_reindex_product_metadata.lambda_arn
    ]
  }
}

data "aws_iam_policy_document" "jenkins_reindex_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "reindex_product_metadata_invoke_role" {
  name                  = "${var.environment}-reindex-product-metadata-invoke-role"
  force_detach_policies = true
  assume_role_policy    = data.aws_iam_policy_document.jenkins_reindex_assume_role_policy.json

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }
}

resource "aws_iam_policy" "reindex_product_metadata_invoke_policy" {
  name   = "${var.environment}-reindex-product-metadata-invoke-policy"
  policy = data.aws_iam_policy_document.reindex_product_metadata_invoke_policy.json

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }
}

resource "aws_iam_role_policy_attachment" "reindex_product_metadata_invoke_policy_attachment" {
  role       = aws_iam_role.reindex_product_metadata_invoke_role.name
  policy_arn = aws_iam_policy.reindex_product_metadata_invoke_policy.arn
}