# Lambda definition for MatchAudio step

locals {
  match_lambda_name = "${var.lambda_name_prefix}-${var.service_name}-match"
}

module "lambda_content_match_audio_match" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment              = var.environment
  application_family       = var.application_family
  lambda_name              = local.match_lambda_name
  lambda_description       = "Find matches for audio fingerprint among publicly released audio."
  vpc_id                   = var.vpc_id
  vpc_subnet_ids           = var.vpc_subnet_ids
  use_container_image      = true
  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    SENTRY_DSN  = module.sentry_lambda_content_match_audio_match.sentry_key_dsn_public_output
  }

  # Added to fix datadog logging until ddtrace version can be upgraded
  datadog_advanced_merge_xray_traces_enabled = false

  lambda_function_reserved_concurrent_executions = var.lambda_function_reserved_concurrent_executions
}

module "lambda_content_match_audio_match_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.match_secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = local.match_lambda_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "datadog_lambda_content_match_audio_match" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = local.match_lambda_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints

  lambda_error_monitor_enabled      = false
  lambda_invocation_monitor_enabled = false
  lambda_throttle_monitor_enabled   = false
}

module "sentry_lambda_content_match_audio_match" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = local.match_lambda_name
  application_family = var.application_family
}