locals {
  start_sfn_lambda_name = "${var.lambda_name_prefix}-start-${var.sfn_name_prefix}-${var.service_name}"
}

data "aws_sfn_state_machine" "sfn_content_match_audio_arn" {
  name = "${var.environment}-${var.sfn_name_prefix}-${var.service_name}"
}

data "aws_iam_policy_document" "start_sfn_content_policy_document" {
  statement {
    actions = [
      "states:StartExecution",
    ]

    resources = [
      data.aws_sfn_state_machine.sfn_content_match_audio_arn.arn
    ]
  }
}

resource "aws_iam_policy" "start_sfn_content_match_audio_policy" {
  name        = "${var.environment}-start-sfn-content-lambda-policy"
  description = "Start SFN content match audio policy"
  policy      = data.aws_iam_policy_document.start_sfn_content_policy_document.json
}

module "lambda_content_start_sfn_content_match_audio" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.start_sfn_lambda_name

  use_container_image                            = true
  lambda_description                             = "Trigger step function (SFN) content match audio"
  lambda_function_timeout                        = "600"
  lambda_function_reserved_concurrent_executions = var.replication_consumer_lambda_reserved_concurrency
  vpc_enabled                                    = true
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  datadog_enabled                                = true
  datadog_advanced_enabled                       = true
  additional_tags                                = var.additional_tags

  lambda_function_environment_variables = {
    ENVIRONMENT         = var.environment
    SENTRY_DSN          = module.sentry_start_sfn_content_match_audio.sentry_key_dsn_public_output
    STEP_FN_ARN         = data.aws_sfn_state_machine.sfn_content_match_audio_arn.arn
    GRAPHQL_GATEWAY_URL = var.graphql_gateway_url
  }

  msk_event_enabled                      = true
  event_source_mapping_msk_cluster_name  = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid  = var.trigger_msk_cluster_uuid
  event_source_mapping_batch_size        = 1
  kafka_topics = [var.match_audio_msk_topic]
  event_source_mapping_starting_position = "LATEST"

  iam_managed_policy_attachments = [
    aws_iam_policy.start_sfn_content_match_audio_policy.arn
  ]

  # Added to fix datadog logging until ddtrace version can be upgraded
  datadog_advanced_merge_xray_traces_enabled = false
}

# stage datadog creds and create dashboards.
module "datadog_lambda_content_start_sfn_content_match_audio" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = local.start_sfn_lambda_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

module "sentry_start_sfn_content_match_audio" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = local.start_sfn_lambda_name
  application_family = var.application_family
}