locals {
  sfn_v2_name      = "sfn-content-complete-review-v2"
  lambda_prefix_v2 = "arn:aws:lambda:${var.aws_region}:${data.aws_caller_identity.current.account_id}:function:${var.environment}-${var.lambda_name_prefix}-"

  # Template for state machine.
  sfn_content_complete_review_v2_definition = templatefile("${path.module}/sfn-v2.json", {
    lambda_prefix            = local.lambda_prefix_v2,
    default_interval_seconds = var.default_interval_seconds,
    default_max_attempts     = var.default_max_attempts,
    default_backoff_rate     = var.default_backoff_rate,
  })
}

# Step Function (SFN) root role policy document.
data "aws_iam_policy_document" "sfn_content_complete_review_v2_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
        "events.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "sfn_content_complete_review_v2_assume_role" {
  name               = "${var.environment}-${local.sfn_v2_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_content_complete_review_v2_assume_role.json
}

# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_content_complete_review_v2_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${local.sfn_v2_name}",
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${local.sfn_v2_name}:log-stream:*",
      "${aws_cloudwatch_log_group.sfn_v2_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_role_policy" "sfn_content_complete_review_v2_log_event_policy_attachment" {
  name   = "${var.environment}-${local.sfn_v2_name}-log-event-policy"
  role   = aws_iam_role.sfn_content_complete_review_v2_assume_role.id
  policy = data.aws_iam_policy_document.sfn_content_complete_review_v2_log_event_policy_document.json
}

# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "sfn_content_complete_review_v2_invoke_lambda_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      "${local.lambda_prefix_v2}*"
    ]
  }
}

resource "aws_iam_role_policy" "sfn_content_complete_review_v2_invoke_lambda_role_policy" {
  name   = "${var.environment}-${local.sfn_v2_name}-lambda-role-policy"
  role   = aws_iam_role.sfn_content_complete_review_v2_assume_role.id
  policy = data.aws_iam_policy_document.sfn_content_complete_review_v2_invoke_lambda_policy_document.json
}

resource "aws_cloudwatch_log_group" "sfn_v2_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${local.sfn_v2_name}-log-group"
  retention_in_days = 365
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = local.sfn_v2_name
    terraformed        = true
  }
}

data "aws_lambda_function" "datadog_lambda_function_v2" {
  function_name = "DatadogLambdaFunction"
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_log_filter_v2" {
  name            = "${var.environment}-${local.sfn_v2_name}-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_v2_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function_v2.arn
  distribution    = "ByLogStream"
}

resource "aws_sfn_state_machine" "sfn_content_complete_review_v2" {
  name       = "${var.environment}-${local.sfn_v2_name}"
  role_arn   = aws_iam_role.sfn_content_complete_review_v2_assume_role.arn
  definition = local.sfn_content_complete_review_v2_definition

  tags = {
    application_family = var.application_family
    environment        = var.environment
    env                = var.environment
    service_name       = local.sfn_v2_name
    service            = local.sfn_v2_name
    DD_TRACE_ENABLED   = true
    terraformed        = true
  }

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_v2_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }
  tracing_configuration {
    enabled = true
  }
}

module "datadog_sfn_dashboard_v2" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.13.9"
  environment        = var.environment
  service_name       = local.sfn_v2_name
  application_family = var.application_family
  statemachine_arn   = aws_sfn_state_machine.sfn_content_complete_review_v2.arn

  failed_execution_message_log_monitor = {
    enabled        = true
    log_group_name = aws_cloudwatch_log_group.sfn_v2_log_group.name
  }
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

resource "datadog_monitor" "statemachine_v2_failed_log_monitor" {
  count    = 1
  name     = "${var.environment}-${local.sfn_name} failed log monitor"
  type     = "log alert"
  message  = <<EOF
@slack-content-review-support {{#is_alert}}@oncall-content-review-management {{/is_alert}} {{#is_recovery}}@oncall-content-review-management{{/is_recovery}}

The review-complete-v2 state machine has failed. Please identify the failed execution and rerun the state machine to fix the issue

- [${local.sfn_name} AWS Console](https://${var.aws_region}.console.aws.amazon.com/states/home?region=${var.aws_region}#/statemachines/view/${local.sfn_arn})
EOF

  query = "logs(\"@service:stepfunction @evt.name:ExecutionFailed @name:${var.environment}-${local.sfn_name}\").index(\"*\").rollup(\"count\").last(\"30m\") >= 6"

  monitor_thresholds {
    warning            = 1
    warning_recovery   = 0
    critical           = 6
    critical_recovery  = 1
  }

  include_tags        = true
  notify_no_data      = false
  notify_audit        = false
  timeout_h           = 0
  require_full_window = false

  tags = [
    "application_family:${var.application_family}",
    "environment:${var.environment}",
    "env:${var.environment}",
    "service_name:${local.sfn_name}",
    "service:${local.sfn_name}"
  ]
}