data "aws_iam_policy_document" "awal-ingest-flow-control-invoke-policy" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.lambda_awal_ingestion_flow_control.arn,
      data.aws_lambda_function.lambda_copy_assets_to_asheville.arn,
      data.aws_lambda_function.lambda_set_product_to_complete.arn,
    ]
  }
}

data "aws_iam_policy_document" "sme-analytics-ingest-flow-control-invoke-policy" {
  statement {
    effect  = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.lambda_sme_analytics_ingest_flow_control.arn,
    ]
  }
}

data "aws_iam_role" "prod_jenkins_aws_task_agent" {
  name = "prod-jenkins-aws-task-agent"
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.prod_jenkins_aws_task_agent.arn,
      ]
    }
  }
}

# SFN invoke policy.
resource "aws_iam_policy" "awal_ingest_flow_control_invoke_policy" {
  name   = "${var.environment}-awal-ingest-flow-control-invoke-policy"
  policy = data.aws_iam_policy_document.awal-ingest-flow-control-invoke-policy.json
}

# SFN invoke policy.
resource "aws_iam_policy" "sme_analytics_ingest_flow_control_invoke_policy" {
  name   = "${var.environment}-sme-analytics-ingest-flow-control-invoke-policy"
  policy = data.aws_iam_policy_document.sme-analytics-ingest-flow-control-invoke-policy.json
}

# Jenkins agents will assume this role in order to invoke the machine
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-awal-ingest-flow-control-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Jenkins agents will assume this role in order to invoke the flow control Lambdas
resource "aws_iam_role" "sme_analytics_jenkins_invoke_role" {
  name               = "${var.environment}-sme-analytics-ingestion-flow-control-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SFN invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "awal_ingest_flow_control_invoke_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.awal_ingest_flow_control_invoke_policy.arn
}

# Attach SFN invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "sme_analytics_ingest_flow_control_invoke_policy_attachment" {
  role       = aws_iam_role.sme_analytics_jenkins_invoke_role.id
  policy_arn = aws_iam_policy.sme_analytics_ingest_flow_control_invoke_policy.arn
}