# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ddex-ingester/lambda-awal-ingestion-flow-control/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_sfn_state_machine" "sfn_awal_ingester" {
  name = "prod-awal-ingester-sfn"
}

data "aws_rds_cluster" "ddex_ingster_rds" {
  cluster_identifier = "prod-ddex-ingester"
}

data "aws_iam_policy_document" "awal_ingestion_flow_control_sfn_lambda_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
      "states:GetExecutionHistory",
      "states:UpdateStateMachine",
      "states:DescribeStateMachine",
    ]

    resources = [
      data.aws_sfn_state_machine.sfn_awal_ingester.arn,
    ]
  }
}

resource "aws_iam_policy" "awal_ingestion_flow_control_sfn_lambda_policy" {
  name        = "${var.environment}-${var.service_name}-awal-ingestion-flow-control-lambda-sfn-policy"
  description = "trigger_state_machine ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.awal_ingestion_flow_control_sfn_lambda_policy_document.json
}

module "lambda_awal_ingestion_flow_control" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  lambda_name              = "${var.service_name}-awal-ingestion-flow-control"
  lambda_description       = "Handles AWAL ingestion flow control"
  use_container_image      = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    Environment            = var.environment
    LOGGER_DSN             = var.logger_dsn
    SENTRY_DSN             = module.sentry_awal_ingestion_flow_control_lambda.sentry_key_dsn_public_output
    RDS_HOST               = data.aws_rds_cluster.ddex_ingster_rds.endpoint
    RDS_DB_NAME            = data.aws_rds_cluster.ddex_ingster_rds.database_name
    RDS_RW_USER            = var.rds_rw_user
    AWAL_INGESTION_SFN_ARN = data.aws_sfn_state_machine.sfn_awal_ingester.arn
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = ["subnet-067a6b45b079d7296", "subnet-043d235081c966332"] # temporarily hard-code subnets
  lambda_function_reserved_concurrent_executions = 1
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/prod-ddex-ingester-common-lambda-policy",
    "arn:aws:iam::437795906767:policy/prod-ddex-ingester-rds-rw-password-secrets-policy",
    aws_iam_policy.awal_ingestion_flow_control_sfn_lambda_policy.arn
  ]
}

module "datadog_awal_ingestion_flow_control_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.1"

  environment                       = var.environment
  service_name                      = "${var.service_name}-awal-ingestion-flow-control"
  lambda_invocation_monitor_enabled = false
}

module "sentry_awal_ingestion_flow_control_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-awal-ingestion-flow-control"
  application_family = var.application_family
}