# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ddex-ingester/lambda-find-or-create-account/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

data "aws_rds_cluster" "ddex_ingster_rds" {
  cluster_identifier = "${var.environment}-ddex-ingester"
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "lambda_find_or_create_account" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-find-or-create-account-${var.environment}"
  lambda_name              = "${var.service_name}-find-or-create-account"
  lambda_description       = "Handles find_or_create_account"
  use_container_image      = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    Environment         = var.environment
    LOGGER_DSN          = var.logger_dsn
    SENTRY_DSN          = module.sentry_find_or_create_account_lambda.sentry_key_dsn_public_output
    RDS_HOST            = data.aws_rds_cluster.ddex_ingster_rds.endpoint
    RDS_DB_NAME         = data.aws_rds_cluster.ddex_ingster_rds.database_name
    RDS_RW_USER         = var.rds_rw_user
    SNOWFLAKE_USER      = var.snowflake_user
    SNOWFLAKE_SCHEMA    = var.snowflake_schema
    SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    SNOWFLAKE_ACCOUNT   = var.snowflake_account
    SNOWFLAKE_DATABASE  = var.snowflake_database
    SNOWFLAKE_ROLE      = var.snowflake_role
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = ["subnet-067a6b45b079d7296", "subnet-043d235081c966332"] # temporarily hard-code subnets
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/prod-ddex-ingester-common-lambda-policy",
    "arn:aws:iam::437795906767:policy/prod-ddex-ingester-rds-rw-password-secrets-policy"
  ]
}

module "sentry_find_or_create_account_lambda" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  environment        = var.environment
  service_name       = "${var.service_name}-find-or-create-account"
  application_family = var.application_family
}

module "datadog_find_or_create_account_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.1"

  environment                       = var.environment
  service_name                      = "${var.service_name}-find-or-create-account"
  lambda_invocation_monitor_enabled = false
}

module "m2m_secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"
  environment        = var.environment
  service_name       = var.lambda_name
  application_family = var.application_family
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
  application_family = var.application_family
}