# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ddex-ingester/lambda-report-errors/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_rds_cluster" "ddex_ingster_rds" {
  cluster_identifier = "prod-ddex-ingester"
}

data "aws_iam_policy_document" "send_ingestion_emails" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:ses:us-east-1:437795906767:identity/theorchard.com",
      "arn:aws:ses:us-east-1:437795906767:configuration-set/prod-ses-email-events",
    ]
    actions = [
      "ses:SendEmail",
      "ses:SendRawEmail"
    ]
  }
}

resource "aws_iam_policy" "send_ingestion_emails" {
  name        = "${var.environment}-ddex-ingester-report-errors-lambda-policy"
  description = "report_errors ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.send_ingestion_emails.json
}

module "lambda_report_errors" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-report-errors-${var.environment}"
  lambda_name              = "${var.service_name}-report-errors"
  lambda_description       = "Emails errors to relevant parties"
  use_container_image      = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    Environment                             = var.environment
    LOGGER_DSN                              = var.logger_dsn
    SENTRY_DSN                              = module.sentry_report_errors_lambda.sentry_key_dsn_public_output
    OA_USER                                 = var.oa_user
    GRAPHQL_GATEWAY_URL                     = var.graphql_gateway_url
    REPORT_ERRORS_CC                        = var.report_errors_cc
    EMAIL_FROM_ADDRESS                      = var.email_from_address
    VIDOPS_EMAIL_ADDRESS                    = var.vidops_email_address
    SOM_LIVRE_EMAIL_ADDRESSES               = var.som_livre_email_addresses
    REPORT_ERRORS_SME_ANALYTICS_DUMMY_EMAIL = var.report_errors_sme_analytics_dummy_email
    RDS_HOST                                = data.aws_rds_cluster.ddex_ingster_rds.endpoint
    RDS_DB_NAME                             = data.aws_rds_cluster.ddex_ingster_rds.database_name
    RDS_RW_USER                             = var.rds_rw_user
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = ["subnet-067a6b45b079d7296", "subnet-043d235081c966332"] # temporarily hard-code subnets
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/prod-ddex-ingester-common-lambda-policy",
    "arn:aws:iam::437795906767:policy/prod-ddex-ingester-rds-rw-password-secrets-policy",
    aws_iam_policy.send_ingestion_emails.arn
  ]
}

module "datadog_report_errors_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.1"

  environment                       = var.environment
  service_name                      = "${var.service_name}-report-errors"
  lambda_invocation_monitor_enabled = false
}

module "sentry_report_errors_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  application_family = var.application_family
  service_name       = "${var.service_name}-report-errors"
}