# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ddex-ingester/lambda-trigger-state-machine/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_iam_policy_document" "trigger_state_machine_lambda_policy_document" {
  statement {
    actions = [
      "states:StartExecution",
    ]

    resources = [
      data.aws_sfn_state_machine.sfn_ddex_ingester.arn,
    ]
  }
}

resource "aws_iam_policy" "trigger_state_machine_lambda_policy" {
  name        = "${var.environment}-ddex-ingester-trigger-state-machine-lambda-policy"
  description = "trigger_state_machine ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.trigger_state_machine_lambda_policy_document.json
}

data "aws_sfn_state_machine" "sfn_ddex_ingester" {
  name = "prod-ddex-ingester-sfn"
}

# Lambda defintion for 'trigger-state-machine' lambda
module "lambda_trigger_state_machine" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-trigger-state-machine-${var.environment}"
  lambda_name              = "${var.service_name}-trigger-state-machine"
  lambda_description       = "Handles triggering the DDEX ingester state machine with appropriate name"
  use_container_image      = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    Environment            = var.environment
    LOGGER_DSN             = var.logger_dsn
    SENTRY_DSN             = module.sentry_trigger_state_machine_lambda.sentry_key_dsn_public_output
    DDEX_STATE_MACHINE_ARN = data.aws_sfn_state_machine.sfn_ddex_ingester.arn
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    aws_iam_policy.trigger_state_machine_lambda_policy.arn
  ]
}

module "sentry_trigger_state_machine_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  application_family = var.application_family
  service_name       = "${var.service_name}-trigger-state-machine"
}

module "datadog_trigger_state_machine_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.1"

  environment                       = var.environment
  service_name                      = "${var.service_name}-trigger-state-machine"
  lambda_invocation_monitor_enabled = false
}