module "subaccount_mapping_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  env                = var.environment
  bucket_name        = "subaccount-mapping"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "subaccount_mapping_bucket_rw_policy" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject",
    ]

    resources = [
      "${module.subaccount_mapping_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "subaccount_mapping_bucket_rw_policy" {
  name        = "S3-prod-subaccount-mapping-RW"
  description = "Read, Write, Delete access to subaccount-mapping bucket"
  policy      = data.aws_iam_policy_document.subaccount_mapping_bucket_rw_policy.json
  tags = {
    environment        = var.environment
    service_name       = var.lambda_name
    application_family = var.application_family
    terraformed        = true
  }
}