provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/lambda-gda-sforce-kafka-sync/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.6"

  for_each = toset([
    "SALESFORCE_CONSUMER_KEY",
    "SALESFORCE_CONSUMER_SECRET",
    "SALESFORCE_REFRESH_TOKEN",
    "INTEGRATION_TEST_CONSUMER_KEY",
    "INTEGRATION_TEST_CONSUMER_SECRET",
    "INTEGRATION_TEST_REFRESH_TOKEN",
  ])

  environment                    = var.environment
  service_name                   = "lambda-gda-sforce-kafka-sync"
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "gda_sforce_kafka_sync_lambda_sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git?ref=2.0.1"
  environment        = var.environment
  platform           = "python"
  service_name       = var.lambda_name
  application_family = var.application_family
}

module "gda_sforce_kafka_sync_lambda_datadog" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=4.6.0"
  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false
  notification_endpoints            = var.datadog_notification_endpoints
}

data "aws_msk_cluster" "msk_cluster" {
  cluster_name = var.msk_cluster_name
}

module "gda_sforce_kafka_sync_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=2.11.1"

  environment                                       = var.environment
  lambda_name                                       = var.lambda_name
  lambda_description                                = "Sync Contacts from SalesForce into Kafka topic."
  application_family                                = var.application_family
  use_container_image                               = true
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  cloudwatch_event_enabled                          = true
  cloudwatch_event_schedule                         = var.cloudwatch_event_schedule
  datadog_advanced_enabled                          = var.datadog_advanced_enabled

  vpc_subnet_ids          = var.vpc_subnet_ids
  vpc_id                  = var.vpc_id
  dlq_enabled             = var.dlq_enabled
  zappa_s3_policy_enabled = false

  lambda_function_environment_variables = {
    ENVIRONMENT               = var.environment
    BOOTSTRAP_SERVERS         = data.aws_msk_cluster.msk_cluster.bootstrap_brokers_tls
    KAFKA_TOPIC               = var.kafka_topic
    KAFKA_OFFSET_TOPIC        = var.kafka_offset_topic
    GROUP_ID                  = var.group_id
    SALESFORCE_DOMAIN         = var.salesforce_domain
    DD_LAMBDA_HANDLER         = var.lambda_handler
    SENTRY_DSN                = module.gda_sforce_kafka_sync_lambda_sentry.sentry_key_dsn_public_output
  }
}