provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/lambda-looker-gfk/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.4"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
  application_family = var.application_family
}

module "lambda_looker_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=2.0.1"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
}

module "lambda_looker_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=3.0.18"

  environment                       = var.environment
  service_name                      = var.service_name
  lambda_invocation_monitor_enabled = false
}

module "lambda_looker_gfk" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=2.4.4"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = var.service_name

  use_container_image = true
  lambda_description  = "Send an export from Looker file from S3 to GfK FTP server."
  dlq_enabled         = var.dlq_enabled
  vpc_enabled         = true
  vpc_id              = var.vpc_id
  vpc_subnet_ids      = var.vpc_subnet_ids

  datadog_enabled          = true
  datadog_advanced_enabled = var.datadog_advanced_enabled

  lambda_function_environment_variables = {
    Environment  = var.environment
    GFK_FTP_PORT = var.gfk_ftp_port
    GFK_FTP_HOST = var.gfk_ftp_host
    GFK_FTP_PATH = var.gfk_ftp_path
    SENTRY_DSN   = module.lambda_looker_sentry.sentry_key_dsn_public_output
  }

  s3_event_enabled     = var.s3_event_enabled
  s3_event_bucket_name = var.s3_event_bucket_name

  iam_managed_policy_attachments = [
    aws_iam_policy.lambda_looker_gfk_secrets_manager_policy.arn,
  ]

}

data "aws_iam_policy_document" "lambda_looker_gfk_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]
  }

  statement {
    actions = [
      "sns:Publish"
    ]

    effect = "Allow"
    resources = [
      "arn:aws:sns:${var.aws_region}:${data.aws_caller_identity.current.account_id}:${var.environment}-swf-feed-ingestion"
    ]
  }
}

# Create secrets manager policy for lambda-looker-gfk
resource "aws_iam_policy" "lambda_looker_gfk_secrets_manager_policy" {
  name   = "Secretsmanager-${var.environment}-${var.service_name}-secrets-manager-policy"
  policy = data.aws_iam_policy_document.lambda_looker_gfk_secrets_manager_policy.json
}

# CloudWatch Event rule and target.
resource "aws_cloudwatch_event_rule" "input_asset_event_rule" {
  name        = "${var.environment}-lambda-looker-gfk-file-consuming-rule"
  description = "The CloudWatch event rule for getting object events on lambda-looker-gfk bucket."

  event_pattern = jsonencode(
    {
      source      = ["aws.s3"],
      detail-type = ["Object Created"],
      detail = {
        bucket = {
          name = [data.aws_s3_bucket.looker_gfk_bucket.bucket]
        },
        object : {
          key : [{ prefix : var.s3_event_filter_prefix }]
        }
      }
    }
  )

  tags = {
    service_name       = "${var.environment}-eventbridge-s3-lambda-looker-gfk"
    environment        = var.environment
    application_family = var.application_family
    terraformed        = true
  }
}

resource "aws_cloudwatch_event_target" "lambda_looker_gfk_target" {
  target_id = "${var.environment}_lambda_looker_gfk_target_rule"
  rule      = aws_cloudwatch_event_rule.input_asset_event_rule.name
  arn       = module.lambda_looker_gfk.lambda_arn
}

resource "aws_lambda_permission" "lambda_looker_gfk_permissions" {
  statement_id  = "AllowInvocationFromCloudWatchS3Notifications"
  action        = "lambda:InvokeFunction"
  function_name = module.lambda_looker_gfk.lambda_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.input_asset_event_rule.arn
}